Shader學習筆記 例子： Mesh Filter ： 存儲一個Mesh（網格，模型的網格，就是模型的由哪些三角面組成，組成一個什麼樣子的模型，三角面的一些頂點信息） Mesh Renderer:用來渲染一個模型的外觀，就是樣子， 按照 mesh給它皮膚，給它顏色 通過Material（材質）控制 ...
Shader學習筆記
例子：
Shader "SrfShader1"{
//定義顯示在Inspector中的變數，並從Inspector中獲取值
Properties{
_Color("Color",Color)=(1,1,1,1) //用來融合漫反射或2d紋理的顏色
_MainTex("MainTex (RGB)",2D)="white"{} //主2d紋理圖片色
_Gloss("Gloss",Range(1,100)) = 10
}
//可以多個SubShader塊(渲染方案)，從第一個開始匹配，直到可用，否則匹配FallBack方案
SubShader{
Pass{
Tags{"LightMode"="ForwardBase"}//標簽
CGPROGRAM
//引入unity內置的文件，取得第一個直射光源（這樣可以訪問它的屬性：顏色_LightColor0,法線_World2Object,位置_WorldSpaceLightPos0）
#include "Lighting.cginc"
//聲明兩個函數，頂點函數和片元函數（系統自動調用這兩個函數）
#pragma vertex vert
#pragma fragment frag
//定義變數，從Properties中獲得的材質球的顏色
fixed4 _Color;
sampler2D _MainTex; //2d紋理
float4 _MainTex_ST; //該2d紋理的縮放和偏移
half _Gloss;
//定義結構體(定義了一個頂點的3個屬性：頂點坐標、法線方向、紋理貼圖中的坐標)
struct a2v{
float4 vertex:POSITION; //告訴Unity把模型空間下的頂點坐標填充給該變數vertex
float3 normal:NORMAL; //告訴Unity把模型空間下的法線方向填充給normal
float4 texcoord:TEXCOORD0; //告訴Unity把第一套紋理坐標UV填充給texcoord
};
struct v2f{
float4 position:SV_POSITION; //填充為剪裁空間的坐標
float3 worldNormal:COLOR0;
float3 worldVertex:COLOR1;
float2 uv:TEXCOORD1;
};
//定義頂點函數(對模型的每個頂點調用,把結構a2v中的值賦值給f,把返回值應用到每個頂點,根據頂點之間的插值來填充非頂點位置)
//把邏輯寫在這裡，表示使用逐頂點計算的光照色
v2f vert(a2v v){
v2f f;
//把把模型空間下的頂點坐標轉換為剪裁空間的頂點坐標
f.position = mul(UNITY_MATRIX_MVP,v.vertex);
f.worldNormal = mul(v.normal,(float3x3)_World2Object);
//f.worldNormal = UnityObjectToWorldNormal(v.normal);//也可以使用UnityCG.cginc中一些常用的函數
f.worldVertex = mul(v.vertex,_World2Object).xyz;
f.uv = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw; //取到貼圖的UV坐標的縮放倍數+偏移
return f;
}
//定義片元函數(對剪裁空間下的模型上的每個像素點調用，把返回值顏色應用到每個對應的像素點)
//把邏輯寫在這裡，表示使用逐像素計算的光照色
fixed4 frag(v2f f):SV_Target{
//把把模型空間下的法線方向轉換為模型空間的法線方向，並取得該法線的單位向量
fixed3 normalDir = normalize(f.worldNormal);
//取得光的位置（這裡是平行光）的單位向量
fixed3 lightDir = normalize(_WorldSpaceLightPos0.xyz);
//取得紋理貼圖當前像素點的顏色,並和指定顏色融合
fixed3 texture2dColor = tex2D(_MainTex,f.uv.xy)*_Color.rgb;
//1.取得漫反射的顏色(使用半蘭伯特光照模型)，融合貼圖顏色
fixed3 diffuse = _LightColor0.rgb * (dot(normalDir,lightDir)*0.5+0.5) * texture2dColor;
//取得反射光的方向，利用reflect()方法，根據入射光和法線來取
//fixed3 reflectDir = normalize(reflect(-lightDir,normalDir));
//取得視野方向，_WorldSpaceCameraPos表示視野位置
fixed3 viewDir = normalize( _WorldSpaceCameraPos.xyz - f.worldVertex );
//取得平行光和視野方向的平分線方向單位向量（兩個向量相加除2就等於平分線向量）
fixed3 halfDir = normalize(lightDir+viewDir);
//2-1.取得反射光顏色（Blinn光照模型）
//fixed3 specular = _LightColor0.rgb * pow(max(dot(reflectDir,viewDir),0),_Gloss);
//2-2.取得反射光顏色（Blinn-Phong光照模型）
fixed3 specular = _LightColor0.rgb * pow(max(dot(normalDir,halfDir),0),_Gloss);
//3.各種影響的顏色疊加：漫反射 + 高光反射 + Unity內置環境光顏色與貼圖色融合(融合後效果更好，不會只是變亮或變暗)
fixed3 tempColor = diffuse + specular + UNITY_LIGHTMODEL_AMBIENT.rgb*texture2dColor;
return fixed4(tempColor,1);
}
ENDCG
}
}
FallBack "Diffuse"
}Mesh Filter ： 存儲一個Mesh（網格，模型的網格，就是模型的由哪些三角面組成，組成一個什麼樣子的模型，三角面的一些頂點信息）
Mesh Renderer:用來渲染一個模型的外觀，就是樣子， 按照 mesh給它皮膚，給它顏色
通過Material（材質）控制模型渲染的樣子
Material貼圖(可以沒有，可以是一個單純的顏色)
書籍
unity shader 入門精要（樂樂程式猿）
unity 3d shaderlab開發實戰詳解（第二版）
unity 5.x shaders and effects cookbook(中文版 unity著色器和屏幕特效開發秘籍)
CG語言教程官網
http://http.developer.nvidia.com/CgTutorial/cg_tutorial_frontmatter.html
一些網站
www.shadertoy.com
http://blog.csdn.net/poem_qianmo?viewmode=contents
數學函數線上演示
http://zh.numberempire.com/graphingcalculator.php
UnityCG.cginc中一些常用的函數，這個文件預設會自動引入
//攝像機方向（視角方向）
float3 WorldSpaceViewDir(float4 v) 根據模型空間中的頂點坐標 得到 （世界空間）從這個點到攝像機的觀察方向
float3 UnityWorldSpaceViewDir(float4 v) 世界空間中的頂點坐標==》世界空間從這個點到攝像機的觀察方向
float3 ObjSpaceViewDir(float4 v) 模型空間中的頂點坐標==》模型空間從這個點到攝像機的觀察方向
//光源方向
float3 WorldSpaceLightDir(float4 v) 模型空間中的頂點坐標==》世界空間中從這個點到光源的方向
float3 UnityWorldSpaceLightDir(float4 v) 世界空間中的頂點坐標==》世界空間中從這個點到光源的方向
float3 ObjSpaceLightDir(float4 v) 模型空間中的頂點坐標==》模型空間中從這個點到光源的方向
//方向轉換
float3 UnityObjectToWorldNormal(float3 norm) 把法線方向 模型空間==》世界空間
float3 UnityObjectToWorldDir(float3 dir) 把方向 模型空間=》世界空間
float3 UnityWorldToObjectDir(float3 dir) 把方向 世界空間=》模型空間什麼是OpenGL、DirectX
shader可以認為是一種渲染命令 ，由opengl 或者dx進行解析，來控制渲染豐富多彩的圖形
OpenGL 使用GLSL 編寫shader
DirectX 使用HSSL 編寫shader
英偉達 CG 編寫shader（跨平臺）
Unity Shader的分類
使用的是ShaderLab編寫Unity中的Shader
1,錶面著色器 Surface Shader
2,頂點/片元著色器 Vertex/Fragment Shader
3,固定函數著色器 Fixed Function Shader
Unityshader中屬性的類型有哪些
_Color("Color",Color)=(1,1,1,1)
_Vector("Vector",Vector)=(1,2,3,4)
_Int("Int",Int)= 34234
_Float("Float",Float) = 4.5
_Range("Range",Range(1,11))=6
_2D("Texture",2D) = "red"{}
_Cube("Cube",Cube) = "white"{}
_3D("Texure",3D) = "black"{}
傳遞步驟：1-3
1.從應用程式傳遞到頂點函數的語義有哪些a2v
POSITION 頂點坐標（模型空間下的）
NORMAL 法線( 模型空間下)
TANGENT 切線（模型空間）
TEXCOORD0~ｎ 紋理坐標(0-1的值)
COLOR 頂點顏色
2.從頂點函數傳遞給片元函數的時候可以使用的語義
SV_POSITION 剪裁空間中的頂點坐標（一般是系統直接使用）
COLOR0 可以傳遞一組值 4個
COLOR1 可以傳遞一組值 4個
TEXCOORD0~7 傳遞紋理坐標
3.片元函數傳遞給系統
SV_Target 顏色值，顯示到屏幕上的顏色
聲明兩個函數，頂點函數和片元函數（系統自動調用這兩個函數）
#pragma vertex vert
#pragma fragment frag
逐頂點計算光照，效果較差，頂點之間的過度跡象明顯，但渲染速度較快
v2f vert(a2v v){.....}
逐像素計算光照，效果較好，平滑過渡，但渲染速度較慢
fixed4 frag(v2f f):SV_Target{...}
什麼是光照模型
光照模型就是一個公式，使用這個公式來計算在某個點的光照效果（模擬現實中的效果）
標準光照模型
在標準光照模型裡面，我們把進入攝像機的光分為下麵四個部分
1.自發光
2.高光反射（根據法線直接反射，類似鏡子）
3.漫反射 Diffuse = 直射光顏色 * max(0,cos夾角(光和法線的夾角) ) cosθ = 光方向· 法線方向
4.環境光
Tags{ "LightMode"="ForwardBase" }
只有定義了正確的LightMode才能得到一些Unity的內置光照變數
#include "Lighting.cginc"
引入unity的內置的文件，取得第一個直射光源（這樣可以訪問它的屬性）
normalize() 用來把一個向量，單位化（原來方向保持不變，長度變為1），單位向量
max() 用來取得函數中最大的一個
dot 用來取得兩個向量的點積
_WorldSpaceLightPos0 取得平行光的位置
_LightColor0取得平行光的顏色
UNITY_MATRIX_MVP 這個矩陣用來把一個坐標從模型空間轉換到剪裁空間
_World2Object 這個矩陣用來把一個方向從世界空間轉換到模型空間
UNITY_LIGHTMODEL_AMBIENT 用來獲取環境光，可在Window>>Linghting菜單裡面的Ambient Source設置
融合：兩個顏色相乘，融合後混合了兩種顏色，但亮度可能變暗
疊加：兩個顏色相加，相加後亮度一般會增強
漫反射：
蘭伯特光照模型：背光部分是純黑的
Diffuse = 直射光顏色 * max(0, cosθ) ，其中cosθ = dot(光方向,法線方向)，即：點積
半蘭伯特光照模型：背光部分不會全黑
Diffuse = 直射光顏色 （cosθ0.5 +0.5）
高光反射：
Blinn光照模型
Specular= 直射光 * pow(max(cosθ,0),10) θ:是反射光方向和視野方向的夾角
Blinn-Phong光照模型
Specular=直射光 * pow(max(cosθ,0),10) θ:是法線和x的夾角 x 是平行光和視野方向的平分線
shader中的各種空間坐標
http://blog.csdn.net/lyh916/article/details/50906272
什麼是切線空間（法線貼圖使用切線空間，就可以通用於不同模型）
http://blog.csdn.net/bonchoix/article/details/8619624
法線貼圖：顯示為藍色的圖片，使用切線空間
法線坐標處理為像素值：
pixel = (normal+1)/2
像素值處理為法線坐標：
normal = pixel*2 - 1
法線貼圖的使用（凹凸調節+透明度）
Shader "Rock Alpha"{
Properties{
//_Diffuse("Diffuse Color",Color) = (1,1,1,1)
_Color("Color",Color) = (1,1,1,1)
_MainTex("Main Tex",2D) = "white"{}
_NormalMap("Normal Map",2D) = "bump"{} //法線貼圖
_BumpScale("Bump Scale",Float)=1 //用來調節凹凸
_AlphaScale("Alpha Scale",Float)=1 //調節透明度
}
SubShader{
//用於透明度渲染
Tags{ "Queue"="Transparent" "IngnoreProjector"="True" "RenderType"="Transparent" }
Pass{
Tags{ "LightMode" = "ForwardBase" }
//以下兩個用於透明度渲染
ZWrite Off
Blend SrcAlpha OneMinusSrcAlpha
CGPROGRAM
#include "Lighting.cginc"
#pragma vertex vert
#pragma fragment frag
//fixed4 _Diffuse;
fixed4 _Color;
sampler2D _MainTex;
float4 _MainTex_ST;
sampler2D _NormalMap;
float4 _NormalMap_ST;
float _BumpScale;
float _AlphaScale;
struct a2v {
float4 vertex:POSITION;
float3 normal:NORMAL;
float4 tangent:TANGENT;//tangent.w是用來確定切線空間中坐標軸的方向的
float4 texcoord:TEXCOORD0;
};
struct v2f {
float4 svPos:SV_POSITION;
//float3 worldNormal:TEXCOORD0;
//float4 worldVertex:TEXCOORD1;
float3 lightDir : TEXCOORD0;
float4 uv:TEXCOORD1; //貼圖坐標存在xy，法線貼圖存在zw
};
v2f vert(a2v v) {
v2f f;
f.svPos = mul(UNITY_MATRIX_MVP, v.vertex);
//f.worldNormal = UnityObjectToWorldNormal(v.normal);
//f.worldVertex = mul(v.vertex, _World2Object);
f.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
f.uv.zw = v.texcoord.xy * _NormalMap_ST.xy + _NormalMap_ST.zw;
TANGENT_SPACE_ROTATION;//調用這個巨集之後，會得到一個矩陣 rotation 這個矩陣用來把模型空間下的方向轉換成切線空間下
//ObjSpaceLightDir(v.vertex)//得到模型空間下的平行光方向
f.lightDir = mul(rotation, ObjSpaceLightDir(v.vertex)); //得到切線空間下的平行光方向
return f;
}
fixed4 frag(v2f f) :SV_Target{
//fixed3 normalDir = normalize(f.worldNormal);
fixed4 normalColor = tex2D(_NormalMap,f.uv.zw);
fixed3 tangentNormal = UnpackNormal(normalColor);//UnpackNormal()轉換為切線空間下的法線
tangentNormal.xy = tangentNormal.xy*_BumpScale;//調節凹凸
tangentNormal = normalize(tangentNormal);
fixed3 lightDir = normalize(f.lightDir);
fixed4 texColor = tex2D(_MainTex, f.uv.xy)*_Color;
fixed3 diffuse = _LightColor0.rgb * texColor.rgb * max(dot(tangentNormal, lightDir), 0);
fixed3 tempColor = diffuse + UNITY_LIGHTMODEL_AMBIENT.rgb*texColor;
return fixed4(tempColor,_AlphaScale*texColor.a );//透明度混合了_AlphaScale和texColor.a
}
ENDCG
}
}
Fallback "Specular"
}
