基於ZYNQ的OV5640攝像頭的sobel運算元邊緣檢測

来源:https://www.cnblogs.com/Lclone/archive/2023/04/01/17278432.html
-Advertisement-
Play Games

最近鴿了挺久的，因為最近要做課設，再加上被這個工程的調試給難到了。 在做該工程的時候，有一個良好的項目管理習慣會讓開發的時候不會讓人那麼的高血壓。 特別要註意的是，非同步FIFO的讀寫時鐘的速率匹配問題，這個問題卡了我好久。 1、sobel運算元 Sobel 演算法是像素圖像邊緣檢測中最重要的運算元之一，在 ...


最近鴿了挺久的，因為最近要做課設，再加上被這個工程的調試給難到了。
在做該工程的時候，有一個良好的項目管理習慣會讓開發的時候不會讓人那麼的高血壓。
特別要註意的是，非同步FIFO的讀寫時鐘的速率匹配問題，這個問題卡了我好久。

1、sobel運算元

Sobel 演算法是像素圖像邊緣檢測中最重要的運算元之一，在機器學習、數字媒體、電腦
視覺等信息科技領域起著舉足輕重的作用。在技術上，它是一個離散的一階差分運算元，用來
計算圖像亮度函數的一階梯度之近似值。在圖像的任何一點使用此運算元，將會產生該點對應
的梯度矢量或是其法矢。
Sobel 邊緣檢測通常帶有方向性，可以只檢測豎直邊緣或垂直邊緣或都檢測。
實現步驟：
第一步：Sobel 提供了水平方向和垂直方向兩個方向的濾波模板。設 x 方向和 y 方向
的捲積因數分別為 Gx和 Gy，模板如下所示，A 為原圖像。
image
第二步：矩陣運算後，就得到橫向灰度值 Gx 和縱向灰度值 Gy，然後通過如下公式進
行計算出該點的灰度值：
image
這個運算比較複雜，涉及到平方和開根（FPGA 不擅長），可以採用取近似值計算方法，對
於最終結果影響不大
image
第三步：設置一個閾值 threshold，對數據進行比較然後輸出二值圖像

2、圖像灰度演算法

圖像數據中，含有RGB三種顏色的數據，如果一起處理的話，要很大的的運算量和位寬，為了減小運算量，可以將24位的RGB數據轉化為8位的灰度圖像。
雖然丟失了一些顏色等級，但是從整幅圖像的整體和局部的色彩以及亮度等級分佈特征來看，灰度圖描述與彩色圖的描述是一致的。一般有分量法、最大值法、平均值法、加權平均法四種方法對彩色圖像進行灰度化。

然後本次採用的是平均值法。

將彩色圖像中的三分量亮度求平均得到一個灰度值。如下:
image

上式中有除法，考慮到在 FPGA 中實現除法比較的消耗資源，這裡在實現前可以先做
如下的近似處理。可以將上面公式乘以 3/256，這樣就需要同時乘以 256/3 保證公式的正確
性。公式處理過程如下：
image
對 256/3 做近似取整處理，將 256/3 替換成 85，則公式變為如下。
image

這樣式子中除以 256 就可以採用移位方法來處理，式子變為如下：
image

上面處理過程中使用是對 256/3 的近似處理，當然這裡可以採用其他數據，比如
512/3、1024/3、2048/3 等等，基本的原則是將平均公式法中分母的 3 替換成 2 的冪次的
數，這樣除法就可以使用移位的方式實現，減小 FPGA 中由於存在除法帶來的資源消耗。

3、sobel演算法的實現

該工程用到的運算元需要三行數據才能進行，我們可以先緩存兩行數據，然後接下來的輸入數據加上之前緩存的兩行的數據就是三行數據了，示意圖如下：
image
緩存區像移位寄存器一樣，一個周期輸入一個數據和輸出一個數據，可以用xilinx的RAM-base Shift Register IP核來實現。
但上面僅實現31的模板，要實現33的模板可在每行輸出串聯三組寄存器，以下是示意圖：
image
然後我們就可以取寄存器組裡面的值進行Sobel 演算法的實現了。

4、sobel演算法模塊

本模塊需要

  • 1個16位寬1024深度的非同步FIFO
  • 2個16位寬1024深度的同布FIFO
  • 2個8位寬400深度RAM-base Shift Register IP核

sobel_core_v1_0.v

`timescale 1ns / 1ps
//////////////////////////////////////////////////////////////////////////////////
// Company: GDUT
// Engineer: Lclone
// 
// Create Date: 2023/03/27 22:04:23
// Design Name: sobel_core
// Module Name: sobel_core
// Project Name: sobel_core
// Target Devices: 
// Tool Versions: 
// Description: 
// 
// Dependencies: 
// 
// Revision:
// Revision 0.01 - File Created
// Additional Comments:
// 
//////////////////////////////////////////////////////////////////////////////////


module sobel_core_v1_0
#   (   parameter  LINE_LENGTH = 800,       //行長度
        parameter  LINE_NUM    = 480)       //場長度
    (
        //------系統介面---------
        input        m_clk,                   //主時鐘
        input        rst_n,                   //複位信號
        //------攝像頭介面-------
        input        pclk,                    //像素時鐘
        input [15:0] cam_data,                //圖像數據輸入
        input        data_valid,              //數據有效
        //------maxis介面--------
        input              m_axis_tready,
        output  reg        m_axis_tvalid,
        output      [15:0] m_axis_tdata,
        output  reg        m_axis_tlast,
        output             m_axis_tuser
    );
    
    //------------------cam_fifo的信號-----------------------------
    reg         cam_fifo_data_rd_en;          //cam_fifo 讀使能
    reg         cam_fifo_data_rd_en_r;
    wire [15:0] cam_fifo_data_out;            //cam_fifo讀出數據
    wire [ 9:0] rd_data_count;                //cam_fifo讀出計數
    
    //------------------圖像灰度演算法的信號------------------------
    wire [ 9:0] sum;                          
    reg  [15:0] gray_r;
    wire [ 7:0] gray_8b_o;
    reg         gray_valid;
    //-------------------sbole模塊信號----------------------------
    wire [ 7:0] filter_data_out;
    wire        filter_data_valid;
    //-------------------兩個同步fifo的信號-----------------------
    wire [15:0] fifo_data0;
    wire [15:0] fifo_data1;
    wire [ 9:0] fifo_data_count0;
    wire [ 9:0] fifo_data_count1;
    reg  [ 9:0] out_data_count;
    reg         fifo_flag;
    
    //-------------------場計數信號-------------------------------
    reg  [ 8:0] line_cnt;
    reg         line_end;
    //------------------------------------------------------------
    reg m_axis_act; //m_axis活動信號
    
    always@(posedge m_clk or negedge rst_n) begin
        if(rst_n == 0)
            cam_fifo_data_rd_en <= 0;
        else if(rd_data_count >= LINE_LENGTH/2)//當cam_fifo里的數據大於400個的時候，就進行讀取
            cam_fifo_data_rd_en <= 1;
        else if(rd_data_count <=  2) //當cam_fifo里的數據小於兩個的時候，就暫停讀取
            cam_fifo_data_rd_en <= 0;
        else
            cam_fifo_data_rd_en <= cam_fifo_data_rd_en;
    end
    always @(posedge m_clk) cam_fifo_data_rd_en_r <= cam_fifo_data_rd_en; //延一拍，作為寫入同步fifo的寫信號
    
    always@(posedge m_clk or negedge rst_n) begin
        if(rst_n == 0)
            m_axis_act <= 0;
        else if(fifo_data_count0 >= LINE_LENGTH/2 - 1 ) //當同步fifo0的數據有400個的時候就使axi_stream介面活動
            m_axis_act <= 1;
        else if(fifo_data_count1 <= 1 )//當同步fifo1的數據小於1個的時候就使axi_stream介面暫停活動
            m_axis_act <= 0;
        else
            m_axis_act <= m_axis_act;
    end
    
    always@(posedge m_clk) m_axis_tvalid <= m_axis_act;//延一拍作為tvalid信號與數據同步
    
    always@(posedge m_clk or negedge rst_n) begin//每行數據的最後一個拉高tlast信號
        if(rst_n == 0)
            m_axis_tlast <= 0;
        else if(out_data_count == LINE_LENGTH - 2 & m_axis_tvalid)
            m_axis_tlast <= 1;
        else
            m_axis_tlast <= 0;
    end
    
    always@(posedge m_clk or negedge rst_n) begin//場計數器，為給出幀同步信號而設置的。
        if(rst_n == 0)
            line_cnt <= 0;
        else if(line_cnt == LINE_NUM - 1 & out_data_count == LINE_LENGTH - 1)
            line_cnt <= 0;
        else if(out_data_count == LINE_LENGTH - 1)
            line_cnt <= line_cnt + 1'b1;
        else
            line_cnt <= line_cnt;
    end
   
    
    always@(posedge m_clk or negedge rst_n) begin//輸出計數器，為給出tlast，切換fifo，給出幀同步信號而設置的。
        if(rst_n == 0)
            out_data_count <= 0;
        else if(out_data_count == LINE_LENGTH - 1)
            out_data_count <= 0;
        else if(m_axis_tvalid & m_axis_tready)
            out_data_count <= out_data_count + 1'b1;
        else
            out_data_count <= out_data_count;
    end
    
    always@(posedge m_clk or negedge rst_n) begin
        if(rst_n == 0)
            line_end <= 0;
        else if(line_cnt == LINE_NUM - 1 & out_data_count == LINE_LENGTH - 1)
            line_end <= 1;
        else
            line_end <= 0;
    end
    
    assign m_axis_tuser = (out_data_count == 0 & m_axis_tvalid & m_axis_tready & line_cnt == 0)? 1:0; //每個幀的第一個數據拉高tuser，也就是幀同步信號
    
    //-------------------------------------------圖像灰度演算法------------------------------------------------------
    
    assign sum = {cam_fifo_data_out[15:11],3'b0} + {cam_fifo_data_out[10:5],2'b0} + {cam_fifo_data_out[4:0],3'b0};
    
    always@(posedge m_clk or negedge rst_n)
    begin
    if(rst_n == 0)
        gray_r <= 16'd0;
    else if(cam_fifo_data_rd_en_r)
        gray_r <= (sum << 6)+(sum << 4)+(sum << 2)+ sum;
    else
        gray_r <= 16'd0;
    end
    
    assign gray_8b_o = gray_r[15:8];
    always@(posedge m_clk)
    begin
        gray_valid <= cam_fifo_data_rd_en_r;
    end
    
    //------------------------------------------同步fifo的數據切換--------------------------------------------------
    
    always@(posedge m_clk or negedge rst_n)
    begin
        if(rst_n == 0)
            fifo_flag <= 0;
        else if(out_data_count >= LINE_LENGTH - 1)
            fifo_flag <= 0;
        else if(out_data_count >= LINE_LENGTH/2 - 1)
            fifo_flag <= 1;
        else
            fifo_flag <= fifo_flag;
    end
    
    assign m_axis_tdata = (fifo_flag) ? fifo_data1 : fifo_data0;
    
    //----------------------------------------------------------------------------------------------------------
    
fifo_generator_1 cam_data_fifo (
  .rst(~rst_n),                      // input wire rst
  .wr_clk(pclk),                // input wire wr_clk
  .rd_clk(m_clk),                // input wire rd_clk
  .din(cam_data),                      // input wire [15 : 0] din
  .wr_en(data_valid),                  // input wire wr_en
  .rd_en(cam_fifo_data_rd_en),                  // input wire rd_en
  .dout(cam_fifo_data_out),                    // output wire [15 : 0] dout
  .full(),                    // output wire full
  .empty(),                  // output wire empty
  .rd_data_count(rd_data_count),  // output wire [9 : 0] rd_data_count
  .wr_rst_busy(),      // output wire wr_rst_busy
  .rd_rst_busy()      // output wire rd_rst_busy
);
    
    
fifo_generator_0  fifo_generator_0_inst (
  .clk(m_clk),                // input wire clk
  .srst(~rst_n),              // input wire srst
  .din(cam_fifo_data_out),                // input wire [15 : 0] din
  .wr_en(cam_fifo_data_rd_en_r),            // input wire wr_en
  .rd_en(~fifo_flag & m_axis_act & m_axis_tready),            // input wire rd_en 
  .dout(fifo_data0),              // output wire [15 : 0] dout        //m_axis_tdata
  .full(),              // output wire full
  .empty(),            // output wire empty
  .data_count(fifo_data_count0)  // output wire [9 : 0] data_count
);


sobel_filter
#(  .DATA_WIDTH(8))
sobel_filter_inst
(
    .clk(m_clk),
    .reset_p(~rst_n),
    .data_in(gray_8b_o),
    .data_in_valid(gray_valid),
    .data_in_hs(1'b1),
    .data_in_vs(1'b1),
    .threshold(8'd127),
    //--------------------------
    .data_out(filter_data_out),
    .data_out_valid(filter_data_valid),
    .data_out_hs(),
    .data_out_vs()
    );
    
    
fifo_generator_0 fifo_generator_1_inst (
  .clk(m_clk),                // input wire clk
  .srst(~rst_n),              // input wire srst
  .din({{5{filter_data_out[0]}},{6{filter_data_out[0]}},{5{filter_data_out[0]}}}),// input wire [15 : 0] din
  .wr_en(filter_data_valid),            // input wire wr_en
  .rd_en(fifo_flag & m_axis_act & m_axis_tready),            // input wire rd_en
  .dout(fifo_data1),              // output wire [15 : 0] dout
  .full(),              // output wire full
  .empty(),            // output wire empty
  .data_count(fifo_data_count1)  // output wire [9 : 0] data_count
);
endmodule

sobel_filter.v

`timescale 1ns / 1ps

module sobel_filter
#(  parameter DATA_WIDTH = 8)
(
    input                          clk,
    input                          reset_p,
    input      [DATA_WIDTH - 1:0]  data_in,
    input                          data_in_valid,
    input                          data_in_hs,
    input                          data_in_vs,
    input      [DATA_WIDTH - 1:0]  threshold,
    //--------------------------
    output reg [DATA_WIDTH - 1:0]  data_out,
    output                         data_out_valid,
    output                         data_out_hs,
    output                         data_out_vs
    );
    
    reg  [DATA_WIDTH - 1:0] row0_col0;
    reg  [DATA_WIDTH - 1:0] row0_col1;
    reg  [DATA_WIDTH - 1:0] row0_col2;
    reg  [DATA_WIDTH - 1:0] row1_col0;
    reg  [DATA_WIDTH - 1:0] row1_col1;
    reg  [DATA_WIDTH - 1:0] row1_col2;
    reg  [DATA_WIDTH - 1:0] row2_col0;
    reg  [DATA_WIDTH - 1:0] row2_col1;
    reg  [DATA_WIDTH - 1:0] row2_col2;

    wire [DATA_WIDTH - 1:0] line0_data;
    wire [DATA_WIDTH - 1:0] line1_data;
    wire [DATA_WIDTH - 1:0] line2_data;
    
    reg data_in_valid_dly1;
    reg data_in_valid_dly2;
    reg data_in_valid_dly3;
    reg data_in_hs_dly1;
    reg data_in_hs_dly2;
    reg data_in_hs_dly3;
    reg data_in_vs_dly1;
    reg data_in_vs_dly2;
    reg data_in_vs_dly3;

    wire Gx_is_positive;
    wire Gy_is_positive;
    reg [DATA_WIDTH+1:0] Gx_absolute; //high bit expansion 2bit
    reg [DATA_WIDTH+1:0] Gy_absolute; //high bit expansion 2bit

    

always @(posedge clk or posedge reset_p) begin
 if(reset_p) begin
    row0_col0 <= 'd0;
    row0_col1 <= 'd0;
    row0_col2 <= 'd0;
    row1_col0 <= 'd0;
    row1_col1 <= 'd0;
    row1_col2 <= 'd0;
    row2_col0 <= 'd0;
    row2_col1 <= 'd0;
    row2_col2 <= 'd0;
 end
 else if(data_in_hs && data_in_vs)
 if(data_in_valid) begin
    row0_col2 <= line0_data;
    row0_col1 <= row0_col2;
    row0_col0 <= row0_col1;
    row1_col2 <= line1_data;
    row1_col1 <= row1_col2;
    row1_col0 <= row1_col1;
    row2_col2 <= line2_data;
    row2_col1 <= row2_col2;
    row2_col0 <= row2_col1;
 end
 else begin
    row0_col2 <= row0_col2;
    row0_col1 <= row0_col1;
    row0_col0 <= row0_col0;
    row1_col2 <= row1_col2;
    row1_col1 <= row1_col1;
    row1_col0 <= row1_col0;
    row2_col2 <= row2_col2;
    row2_col1 <= row2_col1;
    row2_col0 <= row2_col0;
 end
 else begin
    row0_col0 <= 'd0;    
    row0_col1 <= 'd0;    
    row0_col2 <= 'd0;    
    row1_col0 <= 'd0;    
    row1_col1 <= 'd0;    
    row1_col2 <= 'd0;    
    row2_col0 <= 'd0;    
    row2_col1 <= 'd0;    
    row2_col2 <= 'd0;    
 end    
end    
    
always @(posedge clk) begin
    data_in_valid_dly1 <= data_in_valid;
    data_in_valid_dly2 <= data_in_valid_dly1;
    data_in_valid_dly3 <= data_in_valid_dly2;
    data_in_hs_dly1 <= data_in_hs;
    data_in_hs_dly2 <= data_in_hs_dly1;
    data_in_hs_dly3 <= data_in_hs_dly2;
    data_in_vs_dly1 <= data_in_vs;
    data_in_vs_dly2 <= data_in_vs_dly1;
    data_in_vs_dly3 <= data_in_vs_dly2;
end

assign data_out_valid = data_in_valid_dly3;
assign data_out_hs = data_in_hs_dly3;
assign data_out_vs = data_in_vs_dly3;
    
shift_register_2taps 
    #(
        .DATA_WIDTH             (DATA_WIDTH)
    )
shift_register_2taps_inst
    (
        .clk                    (clk),
        .shiftin                (data_in),
        .shiftin_valid          (data_in_valid),
        .shiftout               (),
        .taps1x                 (line1_data),
        .taps0x                 (line0_data)
    );
assign line2_data = data_in;

//----------------------------------------------------
// mask x mask y
//[-1,0,1] [ 1, 2, 1]
//[-2,0,2] [ 0, 0, 0]
//[-1,0,1] [-1,-2,-1]
//----------------------------------------------------

assign Gx_is_positive = (row0_col2 + row1_col2*2 + row2_col2) >=
(row0_col0 + row1_col0*2 + row2_col0);
assign Gy_is_positive = (row0_col0 + row0_col1*2 + row0_col2) >=
(row2_col0 + row2_col1*2 + row2_col2);

always @(posedge clk or posedge reset_p) begin
    if(reset_p)
        Gx_absolute <= 'd0;
    else if(data_in_valid_dly1) begin
        if(Gx_is_positive)
            Gx_absolute <= (row0_col2 + row1_col2*2 + row2_col2) - (row0_col0 + row1_col0*2 + row2_col0);
        else
            Gx_absolute <= (row0_col0 + row1_col0*2 + row2_col0) - (row0_col2 + row1_col2*2 + row2_col2);
    end
end

always @(posedge clk or posedge reset_p) begin
    if(reset_p)
        Gy_absolute <= 'd0;
    else if(data_in_valid_dly1) begin
        if(Gy_is_positive)
            Gy_absolute <= (row0_col0 + row0_col1*2 + row0_col2) - (row2_col0 + row2_col1*2 + row2_col2);
    else
            Gy_absolute <= (row2_col0 + row2_col1*2 + row2_col2) - (row0_col0 + row0_col1*2 + row0_col2);
    end
end
//----------------------------------------------------
//result
//----------------------------------------------------
always @(posedge clk or posedge reset_p) begin
    if(reset_p)
        data_out <= 1'b0;
    else if(data_in_valid_dly2) begin
        data_out <= ((Gx_absolute+Gy_absolute)>threshold) ? 1'b0 : 1'b1;
    end
end

endmodule

5、模擬

模擬過程有複雜，調了許久，這裡暫不寫出。

6、上板驗證

本次還是在小梅哥的OV5640_TFT這個工程的基礎上進行修改，並將上面提到的模塊打包成IP核，在block design里進行鏈接。

(1)刪除紅框內的模塊

image

(2)修改OV5640_data_0 IP核

module OV5640_Data_v1_0(
    Rst_n,               //複位
    PCLK,                //像素時鐘
    Vsync,               //場同步信號
    Href,                //行同步信號
    Data,                //數據
    
    DataValid,          //數據有效信號
    DataPixel,          //像素數據
    
    Frame_Clk           //時鐘信號

);

    input Rst_n;            //複位
    input PCLK;             //像素時鐘
    input Vsync;            //場同步信號
    input Href;             //行同步信號
    input [7:0]Data;        //數據
    
    output DataValid;       //數據有效信號
    output [15:0]DataPixel; //像素數據
    
    output Frame_Clk;//時鐘信號

    reg r_Vsync;
    reg r_Href;
    reg [7:0]r_Data;
    
    reg [15:0]r_DataPixel;
    reg r_DataValid;
    reg [12:0]Hcount;
    reg [11:0]Vcount;
    reg [3:0]FrameCnt;
    
    reg Dump_Frame;
    
    assign DataPixel = Dump_Frame ? r_DataPixel : 24'd0;
    assign DataValid = Hcount[0] & Dump_Frame;
    
    
    //攝像頭時鐘使能
    //assign  Frame_Ce = ((Hcount[0]) || (!r_Href)) & Dump_Frame;//1'b1;//(r_DataValid & Dump_Frame)||(!r_DataValid);
    //assign  Frame_Ce = ((!Hcount[0]) || (!r_Href)) & Dump_Frame;//1'b1;//(r_DataValid & Dump_Frame)||(!r_DataValid);
    
    //時鐘為像素時鐘
    assign  Frame_Clk = PCLK;

    //打拍
    always@(posedge PCLK)
    begin
        r_Vsync <= Vsync;
        r_Href <= Href;
        r_Data <= Data;
    end
    
    //行同步信號為1時，行計數器加一（行同步信號為0時歸零）
    always@(posedge PCLK or negedge Rst_n)
    if(!Rst_n)
        Hcount <= 0;
    else if(r_Href)
        Hcount <= Hcount + 1'd1;
    else
        Hcount <= 0;

    //8位轉16位，賦予像素數據
    always@(posedge PCLK or negedge Rst_n)
    if(!Rst_n)
        r_DataPixel <= 0;
    else if(~Hcount[0])
        r_DataPixel <= {r_Data,Data};
    else 
        r_DataPixel[7:0] <= r_Data;
    
    //產生數據有效信號
    always@(posedge PCLK or negedge Rst_n)
    if(!Rst_n)
        r_DataValid <= 0;
    else if(Hcount[0] && r_Href)
        r_DataValid <= 1;
    else
        r_DataValid <= 0;
    
    //行同步信號由0變為1時，列計數器加一（場同步信號為1時歸零）
    always@(posedge PCLK or negedge Rst_n)
    if(!Rst_n)
        Vcount <= 0;
    else if(r_Vsync)
        Vcount <= 0;
    else if({r_Href,Href} == 2'b01)
        Vcount <= Vcount + 1'd1;
    else
        Vcount <= Vcount;
    
    //場同步信號由0變為1時，幀計數加一，最大為10
    always@(posedge PCLK or negedge Rst_n)
    if(!Rst_n)	
        FrameCnt <= 0;
    else if({r_Vsync,Vsync}== 2'b01)begin
        if(FrameCnt >= 10)
            FrameCnt <= 4'd10;
        else
            FrameCnt <= FrameCnt + 1'd1;
    end
    else
        FrameCnt <= FrameCnt;
    
    //當計數大於等於10幀時，Dump_Frame變為1，否則為0
    always@(posedge PCLK or negedge Rst_n)
    if(!Rst_n)
        Dump_Frame <= 0;
    else if(FrameCnt >= 10)
        Dump_Frame <= 1'd1;
    else
        Dump_Frame <= 0;

endmodule

(3)添加打包好的IP核，並建立連接

image

(4)修改SDK中的文件

image
將紅框中的寄存器的值改為圖片所示的值。即使攝像頭輸出400*480的圖像。

最後燒入程式，可觀察到如下結果
image

7、可改進的地方

可以加個按鍵來控制sobel演算法里的閾值。

（該隨筆部分介紹來自小梅哥的教材，侵權刪。）


您的分享是我們最大的動力!

-Advertisement-
Play Games
更多相關文章
  • Pycharm中使用codeium插件，中文註釋顯示為亂碼(方塊字)的解決辦法
    在使用codeium這個AI提示插件的過程中，使用中文註釋，智能提示的提示語，會有可能展示為亂碼、方塊字 如下圖中的灰色提示語: tab以後，就展示正常了。 在中文網上搜了下，沒有相關資料，去codeium的discord頻道問了下，找到瞭解答: 解答為:將首選項->編輯器->字體從“JetBrai ...
  • nacos預設配置啟動
    1.相關組件 |組件 | 說明 |版本地址| | | | | |Nacos |配置及註冊中心 |https://github.com/alibaba/nacos/releases| ps: SpringBoot、SpringCloud和nacos集成版本對應關係對照（版本若對應不上，應用可能會啟動報 ...
  • python學習-基礎案例
    #案例一 列印排序好的數據 #列表方式 lst_name=['林黛玉','薛寶釵','賈元春','賈探春','史湘雲'] lst_sign=['①','②','③','④','⑤'] for i in range(5): print(lst_sign[i],lst_name[i]) print(' ...
  • 08、【算例】openfoam潰壩
    7.1 潰壩 官網 目錄：$FOAM_TUTORIALS/multiphase/interFoam/laminar/damBreak 7.1.1 介紹 本案例使用interFoam兩相演算法，基於流體體積分數（VOF）法，每個網格中的相體積分數（alpha）通過求解一個組分運輸方程確定。物理屬性基於這 ...
  • 看看這份2023年MySQL終級面試題，提升你的內力，給你面試助力
    1、MySQL 中有哪幾種鎖？ （1）表級鎖：開銷小，加鎖快；不會出現死鎖；鎖定粒度大，發生鎖衝突的概率最 高，併發度最低。 （2）行級鎖：開銷大，加鎖慢；會出現死鎖；鎖定粒度最小，發生鎖衝突的概率最 低，併發度也最高。 （3）頁面鎖：開銷和加鎖時間界於表鎖和行鎖之間；會出現死鎖；鎖定粒度界於表 鎖 ...
  • 一次線上OOM問題的個人復盤
    原創：扣釘日記（微信公眾號ID：codelogs），歡迎分享，非公眾號轉載保留此聲明。 上個月，我們一個java服務上線後，偶爾會發生記憶體OOM(Out Of Memory)問題，但由於OOM導致服務不響應請求，健康檢查多次不通過，最後部署平臺kill了java進程，這導致定位這次OOM問題也變得困 ...
  • JAVASE：註解與反射筆記
    JavaSE：註解與反射(Annotation & Reflection) ​ 註解和框架是所有框架的底層，如Mybatis，spring。框架的底層實現機制就是註解和反射。註解相比於註釋，除了能較為直接的表示出這部分模塊的功能，也能實現一定的具體功能。 01 初識註解 1.1 什麼是註解 Anno ...
  • Java多線程（一篇從0講透）
    多線程指的是在一個程式中同時運行多個線程，這些線程可以獨立運行或者相互協作，從而完成更加複雜的任務。Java中的多線程可以使用synchronized關鍵字來實現線程同步，避免多個線程同時訪問共用資源而導致的數據錯誤。此外，Java中還提供了Lock、Condition、Semaphore等類和介面... ...
一周排行
    -Advertisement-
    Play Games
  • 移動開發（一）：使用.NET MAUI開發第一個安卓APP
    移動開發（一）：使用.NET MAUI開發第一個安卓APP 對於工作多年的C#程式員來說，近來想嘗試開發一款安卓APP，考慮了很久最終選擇使用.NET MAUI這個微軟官方的框架來嘗試體驗開發安卓APP，畢竟是使用Visual Studio開發工具，使用起來也比較的順手，結合微軟官方的教程進行了安卓 ...
  • wpf ToggleButton選中效果和一個登錄界面
    前言 QuestPDF 是一個開源 .NET 庫，用於生成 PDF 文檔。使用了C# Fluent API方式可簡化開發、減少錯誤並提高工作效率。利用它可以輕鬆生成 PDF 報告、發票、導出文件等。 項目介紹 QuestPDF 是一個革命性的開源 .NET 庫，它徹底改變了我們生成 PDF 文檔的方 ...
  • 彈幕樹洞項目功能新增篇
    項目地址 項目後端地址： https://github.com/ZyPLJ/ZYTteeHole 項目前端頁面地址： ZyPLJ/TreeHoleVue (github.com) https://github.com/ZyPLJ/TreeHoleVue 目前項目測試訪問地址： http://tree ...
  • 第27篇 sqlserver2022詳細安裝步驟
    話不多說，直接開乾 一.下載 1.官方鏈接下載： https://www.microsoft.com/zh-cn/sql-server/sql-server-downloads 2.在下載目錄中找到下麵這個小的安裝包 SQL2022-SSEI-Dev.exe，運行開始下載SQL server； 二. ...
  • .NET 開源高性能 MQTT 類庫
    前言 隨著物聯網（IoT）技術的迅猛發展，MQTT（消息隊列遙測傳輸）協議憑藉其輕量級和高效性，已成為眾多物聯網應用的首選通信標準。 MQTTnet 作為一個高性能的 .NET 開源庫，為 .NET 平臺上的 MQTT 客戶端與伺服器開發提供了強大的支持。 本文將全面介紹 MQTTnet 的核心功能 ...
  • Serilog文檔翻譯系列（六） - 可用的接收器、增強器、格式化輸出
    Serilog支持多種接收器用於日誌存儲，增強器用於添加屬性，LogContext管理動態屬性，支持多種輸出格式包括純文本、JSON及ExpressionTemplate。還提供了自定義格式化選項，適用於不同需求。 ...
  • 警惕 Visual Studio 屬性求值副作用導致邏輯不符合預期
    目錄簡介獲取 HTML 文檔解析 HTML 文檔測試參考文章 簡介 動態內容網站使用 JavaScript 腳本動態檢索和渲染數據，爬取信息時需要模擬瀏覽器行為，否則獲取到的源碼基本是空的。 本文使用的爬取步驟如下： 使用 Selenium 獲取渲染後的 HTML 文檔 使用 HtmlAgility ...
  • [使用目前最新版]HybridCLR6.9.0+YooAsset2.2.4實現純C# Unity熱更新方案 (一)
    1.前言 什麼是熱更新 游戲或者軟體更新時，無需重新下載客戶端進行安裝，而是在應用程式啟動的情況下，在內部進行資源或者代碼更新 Unity目前常用熱更新解決方案 HybridCLR，Xlua，ILRuntime等 Unity目前常用資源管理解決方案 AssetBundles，Addressable， ...
  • 在 ASP.NET Core Web API 中使用操作篩選器統一處理通用操作
    本文章主要是在C# ASP.NET Core Web API框架實現向手機發送驗證碼簡訊功能。這裡我選擇是一個互億無線簡訊驗證碼平臺，其實像阿裡雲，騰訊雲上面也可以。 首先我們先去 互億無線 https://www.ihuyi.com/api/sms.html 去註冊一個賬號 註冊完成賬號後，它會送 ...
  • 第28篇 如何.net中實現高效可靠數據同步api
    通過以下方式可以高效，並保證數據同步的可靠性 1.API設計 使用RESTful設計，確保API端點明確，並使用適當的HTTP方法（如POST用於創建，PUT用於更新）。 設計清晰的請求和響應模型，以確保客戶端能夠理解預期格式。 2.數據驗證 在伺服器端進行嚴格的數據驗證，確保接收到的數據符合預期格 ...
所有分類