Neo4j數據和Cypher查詢語法筆記

来源:https://www.cnblogs.com/milton/archive/2022/05/02/16179836.html
-Advertisement-
Play Games

Cypher數據結構 Cypher的數據結構: 屬性類型, 複合類型和結構類型 屬性類型 屬性類型 Integer Float String: 'Hello', "World" Boolean: true, false, TRUE, FALSE 結構類型 結構類型 node: 表示一個節點, 由 i ...


Cypher數據結構

Cypher的數據結構: 屬性類型, 複合類型和結構類型

屬性類型

屬性類型

  • Integer
  • Float
  • String: 'Hello', "World"
  • Boolean: true, false, TRUE, FALSE

結構類型

結構類型

  • node: 表示一個節點, 由 id, label 和 map 構成
    • id: 長整數, 全局唯一, node 與 relation 的 id 是共用的一個序列, 都是圖當中的元素id
    • label: 節點標簽, 每個節點可以有多個標簽
    • map: 節點的屬性集合
  • relation: 表示一條邊, 由 id, type, map和兩端的兩個 node的 id 構成
    • id: 長整數, 圖中元素的唯一id
    • type: 邊類型, 只有一個值, 和節點的label作用等價
    • map: 邊的屬性集合
  • path: 表示路徑, 是節點和邊的序列. Path模式: (a)-->()<--(b), 可以有向也可以無向

複合類型

List

註意在 cypher SQL 中, list 和標準 SQL 的區別, 不是用括弧(), 而是用方括弧[]. 有序的值的集合, ['a', 'b'], [1, 2, 3], ['a', 2, n.property, $param], [ ]

  • 由標量類型構成的List, 例如 ['a', 'b'], [1, 2, 3]
  • 由函數range函數生成的List對象, 例如 range(0, 10)表示從start到end的有序數字, Range函數包含兩端
  • 列表(List comprehension): [x IN range(0,10) WHERE x % 2 = 0 | x^3]

Map類型

無序Key/Value對的集合, n是節點, prop是節點的屬性鍵, 引用屬性的值的格式: n.prop

  • 列表的常量表示: { key: 'Value', listKey: [{ inner: 'Map1' }, { inner: 'Map2' }]}
  • Map投影, 用於從節點, 關係和其他Map對象中投影特定元素或變數的值, Map投影的格式是map_variable {map_element, [, …​n]}
    map_variable: 用於引用Map對象, map_element 有四種格式是
    • 屬性選擇器: 格式是 .key, 用於引用Map對象中的屬性
    • 嵌入屬性（Literal entry）, 是一個Key/Value對, 例如, key: <expression>表示嵌入到Map變數中的元素
    • 變數選擇器: 把一個變數的名稱作為Key, 變數的值作為Key的值, 構建一個Key/Value對, 作為Map變數中的元素
    • 屬性全選符號: .*

Map投影的示例, actor是Map變數, nrOfMovies是變數, 從Map變數中獲取name屬性, 並添加額外的屬性nrOfMovies:

MATCH (actor:Person)-[:ACTED_IN]->(movie:Movie)
WITH actor, count(movie) AS nrOfMovies
RETURN actor { .name, nrOfMovies }

創建

創建一個Node

create(
    dis:Disease{
        oid: "xxx1",
        code: "111",
        name: "2hh"
    }
)

create也可以和return搭配, 直接返回結果, create也可以同時創建多個關係

create (m),(s)

創建一個Relation

比如已經有了兩個節點, 我們想關聯上關係

match(
    a: Disease
), (
    b: Disease
)
where a.code="111" and b.code="d1"
create (a)-[r:type]->(b)
return *

給這個線設置一些屬性

match(
    a: Disease{
        code: '111' 
    }
), (
    b: Disease{
        code: 'd1'
    }
)
create(a)-[r:relation{name : a.name + '--' + b.name}]->(b)
return type(r), r.name

同時創建節點和關係

假設不存在節點, 直接創建節點+關係了

create p=(reba:Person{name: 'reba'})-[:WORK_AT]->(nazha:Person{name:'nazha'})<-[:WORK_AT]-(jt:Person{name: 'jt'})
return p

刪除

清空資料庫

對於節點比較少的可以使用

match (n) detach delete n

對於節點比較多的:

  1. 停掉服務
  2. 刪除 graph.db 目錄
  3. 重啟服務

delete 刪除節點

只能刪除不帶連接的節點

match(p:Person{name:'jt'}) delete p
-- or
match(p:Person{id:124}) delete p

刪除節點連帶著全部關係

用 detach 刪除

match(p:Person{name: 'jt'}) detach delete p

只刪除關係

match(p:Person{name: "reba"})-[r:WORK_AT]->() delete r

刪除屬性

remove 刪除節點和關係中的屬性欄位

-- 節點(或關係)的屬性
{
  "name": "診斷",
  "code": "d1",
  "oid": "xxx1"
}
-- 刪除屬性
match(d:Disease{name:"診斷"}) remove d.code
-- return 的 d.code 會變成 null
return d.name, d.oid, d.code

修改

修改/添加一個屬性

match(n {name: 'Andy'})
set n.surname = 'Taylor'
return n.name, n.surname

註意: 如果本身沒有surname 這個屬性, 會自動增加

還有一個高級寫法, 用到了case when

match(n{name: 'Andy'})
set(
    case
    when n.age = 36
    then n End
).wordIn = 'Malmo'
return n.name, n.wordIn

CASE語法

CASE
WHEN predicate THEN result
  [WHEN ...]
  [ELSE default]
END

修改/添加多個屬性

使用等號賦值

match(n{name: 'Peter'})
set n.a1= '1' , n.a2 = '3'
return n

使用map賦值, 註意: 這樣會清除所有原屬性

MATCH (p { name: 'Peter' })
SET p = { name: 'Peter Smith', position: 'Entrepreneur' }
RETURN p.name, p.age, p.position

如果要保留原屬性, 把=變成+=

match (p{name: 'Peter'})
SET p += { age: 38, hungry: TRUE , position: 'Entrepreneur' }
RETURN p.name, p.age, p.hungry, p.position

刪除一個屬性

將這個屬性置為null, 就是刪除一個屬性, 如下

MATCH (n { name: 'Andy' })
SET n.name = NULL RETURN n.name, n.age

刪除所有的屬性

使用一個空的map和等號, 這樣即可刪除節點所有屬性

MATCH (p { name: 'Peter' })
SET p = { }
RETURN p.name, p.age

完全複製一個節點或者關係

SET可用於將所有屬性從一個節點或關係複製到另一個節點. 目標節點或關係的原屬性會被清空.

MATCH (at { name: 'Andy' }),(pn { name: 'Peter' })
set at = pn
return at.name, at.age, at.hungry, pn.name, pn.age

修改標簽（label）

修改一個

MATCH (n { name: 'Stefan' })
SET n:German
RETURN n.name, labels(n) AS labels

修改多個

match(n{name: 'Peter'})
set n:Swedish:Bossman
return n.name, labels(n) as labels

查詢

根據標簽查詢節點

-- 標簽為LABEL1的節點列表
match(d:LABEL1) return d
-- 標簽同時為LABEL1和LABEL2的節點列表
match(d:LABEL1:LABEL2) return d

根據類型查詢邊

-- 類型為 RELATION1 的邊列表
match(n)-[r:RELATION1]-(o) return r

帶屬性條件的查詢

-- 標簽為LABEL1, 且 oid = '123' 的節點列表
match(d:LABEL1{oid: "123"}) return d

Return 關鍵詞

return 的作用是在match匹配上了以後, 選擇哪些返回, 如果能確定返回的屬性, 儘量不要全部返回

Return的語法

需要什麼就返回什麼, *表示返回所有的. 比如

MATCH p =(a { name: 'A' })-[r]->(b)
RETURN *

返回的結果就是滿足上面p, a r, b關係的所有的可能結果

在return中通過as改名

MATCH (a { name: 'A' })
RETURN a.age AS SomethingTotallyDifferent

對於沒有屬性的會返回一個null, 比如

MATCH (n)
RETURN n.age

如果返回的兩個結果, 一個由age這個屬性, 一個沒有, 那麼有的正常返回, 沒有的返回null.

還可以在返回中包含運算, 並且返回的是多個元素也支持

MATCH (a { name: 'A' })
RETURN a.age > 30, "I'm a literal",(a)-->()

DISTINCT

MATCH (a { name: 'A' })-->(b)
RETURN DISTINCT b

OPTIONAL MATCH

這個和match差不多, 區別在於當沒有查到東西的時候, 會返回一個null

比如下麵的結果有值

match(p:Person{
    name: 'reba'
})
optional match (p) -->(x)
return x

但是如果把方向換一下, 結果會變成兩個null

match(p:Person{
    name: 'reba'
})
optional match (p) <--(x)
return x

如果把optional去掉, 結果是 no records

WHERE

使用WHERE指定複雜的查詢條件

MATCH (n)
WHERE n.name = 'Peter' XOR (n.age < 30 AND n.name = 'Timothy') OR NOT (n.name = 'Timothy' OR n.name = 'Peter')
RETURN n.name, n.age

在WHERE中對id進行過濾, 返回標簽為 LABEL1, 元素ID為 1, 2, 3 的元素

MATCH (n:LABEL1) WHERE id(n) IN [1,2,3] RETURN n

在WHERE中對label進行過濾

MATCH (n) WHERE n:Swedish RETURN n.name, n.age

不固定屬性的過濾

with 'AGE' as propname
match (n)
where n[toLower(propname)] < 30
return n.name, n.age

屬性存在性校驗

MATCH (n)
WHERE exists(n.belt)
RETURN n.name, n.belt

以xx字元串開頭

MATCH (n)
WHERE n.name STARTS WITH 'Pet'
RETURN n.name, n.age

以xx字元串結尾

MATCH (n)
WHERE n.name ENDS WITH 'ter'
RETURN n.name, n.age

字元串包含

MATCH (n)
WHERE n.name CONTAINS 'ete'
RETURN n.name, n.age

NOT 的使用

MATCH (n)
WHERE NOT n.name ENDS WITH 'y'
RETURN n.name, n.age

正則表達式的使用

MATCH (n)
WHERE n.name =~ 'Tim.*'
RETURN n.name, n.age

不區分大小寫

MATCH (n)
WHERE n.name =~ '(?i)AND.*'
RETURN n.name, n.age

根據null過濾

MATCH (person)
WHERE person.name = 'Peter' AND person.belt IS NULL RETURN person.name, person.age, person.belt

ORDER BY

首先記住, 不能根據關係或者節點進行排序, 只能根據屬性

MATCH (n)
RETURN n.name, n.age
ORDER BY n.age, n.name

一般order by都是放在return後面

SKIP

從頭開始跳過幾個數據, 一般在Order by 的後面, 如果沒有order by 就放在return後面

MATCH (n)
RETURN n.name
ORDER BY n.name
SKIP toInteger(3*rand()) + 1

LIMIT

limit 一般是在最後了, 控制展示的個數

MATCH (n)
RETURN n.name
ORDER BY n.name
LIMIT toInteger(3 * rand())+ 1

MERGE

這個關鍵字基本上是把create和match合併到一起

基礎用法

merge (robert:Critic{name: '111'})
return robert, labels(robert)

如果不存在這個節點, 會直接創建, 執行後再執行一遍, 作用只是相當於match了.

當然也可以從已經存在的節點中獲取值, 比如

MATCH (person:Person)
MERGE (city:City { name: person.bornIn })
RETURN person.name, person.bornIn, city

從已經存在的節點中, 獲取一些屬性值, 然後進行複製. 當然, 這個操作可以是批量的

on create

這個實際上是一個限定條件, 表達的是當創建的時候, 才執行, 不創建就不執行, 比如:

merge (c:Critic{name:'1112'})
on create set c.create = timestamp()
return c.name, c.create

這個語句中, 如果資料庫中已經存在了一個1112那麼就不會set值, 同樣, 如果不存在, 那麼就會執行set後面的部分.

on match

這個命令和上述表達差不多, 不同的是它是匹配上了就進行set

MERGE (person:Person)
ON MATCH SET person.found = TRUE RETURN person.name, person.found

當然也可以同時設置多個屬性值:

MERGE (person:Person)
ON MATCH SET person.found = TRUE , person.lastAccessed = timestamp()
RETURN person.name, person.found, person.lastAccessed

on create 和on match 合併

MERGE (keanu:Person { name: 'Keanu Reeves' })
ON CREATE SET keanu.created = timestamp()
ON MATCH SET keanu.lastSeen = timestamp()
RETURN keanu.name, keanu.created, keanu.lastSeen

現在資料庫中是沒有這個節點的, 也就是說會進行創建

Merge relationships

MERGE 同樣也能被用來match或者create關係.

比如已經存在兩個節點, 想給他們MERGE一下關係

MATCH (charlie:Person { name: 'Charlie Sheen' }),(wallStreet:Movie { title: 'Wall Street' })
MERGE (charlie)-[r:ACTED_IN]->(wallStreet)
RETURN charlie.name, type(r), wallStreet.title

一下子處理多個關係, 比如:

MATCH (oliver:Person { name: 'Oliver Stone' }),(reiner:Person { name: 'Rob Reiner' })
MERGE (oliver)-[:DIRECTED]->(movie:Movie)<-[:ACTED_IN]-(reiner)
RETURN movie

創建一個無向的連接:

MATCH (charlie:Person { name: 'Charlie Sheen' }),(oliver:Person { name: 'Oliver Stone' })
MERGE (charlie)-[r:KNOWS]-(oliver)
RETURN r

批量操作

有一些批量操作的寫法, 能夠幫助我們快速創建大量節點和關係, 比如:

MATCH (person:Person)
MERGE (city:City { name: person.bornIn })
MERGE (person)-[r:BORN_IN]->(city)
RETURN person.name, person.bornIn, city

將所有Person中出生地和實際的城市直接掛鉤

上面這句話, 我們還可以改寫下:

MATCH (person:Person)
MERGE (person)-[r:BORN_IN]->(city:City { name: person.bornIn })
RETURN person.name, person.bornIn, city

WITH

With關鍵字是連接多個查詢的結果, 即將上一個查詢的結果用作下一個查詢的開始

對聚合函數結果進行篩選

我們用這樣一段話, 來查詢David連接過去的節點, 它向外連接關係大於1的那個節點

match(David{name: 'David'}) --(otherPerson)-->()
with otherPerson, count(*) as cnt
where cnt > 1
return otherPerson.name

match(Anders{name: 'Anders'}) --(otherPerson)-->()
with otherPerson, count(*) as cnt
where cnt > 1
return otherPerson.name

在使用collect之前對結果進行排序

match(n)
with n
where n.name = 'David' or n.name = 'Bossman'
return collect(n.name)

限制搜索路徑分支

MATCH (n { name: 'Anders' })--(m)
WITH m
ORDER BY m.name DESC LIMIT 1
MATCH (m)--(o)
RETURN o.name

UNWIND

unwinding a list

我們先看這樣一句話, 初步瞭解下unwind 的用法:

unwind [1, 2, 3, NULL] as x
return x, 'val' as y

creating a distinct list

with [1, 1, 2, 2] as coll
unwind coll as x
with distinct x
return collect(x) as setOfVals

Using UNWIND with any expression returning a list

其實是在合併列表

with [1, 2] as a, [3, 4] as b
unwind (a + b) as x
return x

Using UNWIND with a list of lists

with [[1, 2], [3, 4], 5] as nested
unwind nested as x
unwind x as y
return x, y

Using UNWIND with an empty list

這是一個用法, 只要unwind的是一個[], 那麼不管一起返回的是什麼, 都會返回一個0rows.

unwind [] as empty
return empty, 'literal_that_is_not_returned'

Using UNWIND with an expression that is not a list

unwind可以被用來檢測是不是一個list

unwind null as x
return x, 'some_itearl'

如果直接unwind一個數字, 會報錯:

unwind 5 as x
return x, '11'

FOREACH

批量的進行修改屬性

match p=(begin)-[*]->(END)
where begin.name = 'A' And END.name = 'D'
foreach(n in nodes(p)| set n.marked = TRUE)

CALL

使用CALL可以調用一些函數, 比如來個最簡單的調用一個庫函數

CALL `db`.`labels`

這樣子可以把所有類名全部列出來

UNION

union 就是把兩個結果合併起來.

MATCH (n:Actor)
RETURN n.name AS name
UNION ALL 
MATCH (n:Movie)
RETURN n.title AS name

如果不用union all 直接用union, 會對結果排除重覆

MATCH (n:Actor)
RETURN n.name AS name
UNION
MATCH (n:Movie)
RETURN n.title AS name

參考


您的分享是我們最大的動力!

-Advertisement-
Play Games
更多相關文章
  • EasyNetQ在.Net5中的應用
    我前面幾篇隨筆介紹了關於幾篇關於SqlSugar的基礎封裝，已經可以直接應用在Winform項目開發上，並且基礎介面也通過了單元測試，同時測試通過了一些Winform功能頁面；本篇隨筆繼續深化應用開發，著手在在.net6框架的Web API上開發應用，也就是基於.net core的Web API應用... ...
  • Linux命令篇 - grep 命令
    本文講講 Ubuntu 18 及以上版本配置 IP 的方法，為什麼它值得一講，因為以 Ubuntu 16 為首的版本的配置方法已經不適用了，如果你還不知道，那本文正好 get 一個新技能。 Ubuntu 18 之後版本配置方法 需要使用 netplan 工具。 對應配置文件： /etc/netpla ...
  • [Linux環境編程學習筆記_1]：I/O-文件與目錄
    文件和目錄 1. 文件系統 我們可以把一個磁碟分成一個或多個分區，每個分區包含一個文件系統，這個文件系統由很多柱面組成，而柱面中有一個非常重要的概念叫做 i 節點。 i 節點包含了文件的大部分信息，如文件類型，文件訪問許可權位，文件大小和指向文件數據的指針等，大多數信息都存在st_mode成員中，有兩 ...
  • 1001-MySQL學習-第一節自習課
    MySQL學習（第一節自習課） 一. 軟體下載、安裝 下載地址：https://dev.mysql.com/downloads/installer/ 位置：mysql->installer->community1 離線安裝版本，不要選帶web路徑的是離線安裝版本。 安裝省略 進程名稱：mysqld. ...
  • 數據類產品設計和實現思路
    聲明 個人原創, 轉載需註明來源 https://www.cnblogs.com/milton/p/16216347.html 數據類產品 最近的項目需要接觸大數據處理相關的產品, 涉及了ETL, 數據挖掘和統計, 數據可視化等功能, 因此瞭解了一下這個行業的產品和工具. 最近看的產品主要是 Qua ...
  • Hadoop（四）C#操作Hbase
    Hbase Hbase是一種NoSql模式的資料庫，採用了列式存儲。而採用了列存儲天然具備以下優勢： 可只查涉及的列，且列可作為索引，相對高效 針對某一列的聚合及其方便 同一列的數據類型一致，方便壓縮 同時由於列式存儲將不同列分開存儲，也造成了讀取多列效率不高的問題 LSM Tree 說到HBase ...
  • 基於邏輯規則的圖譜推理
    導讀： 近年來，知識圖譜在眾多行業場景被大量應用，例如推薦、醫療。為了構造儘可能完備的圖譜，知識圖譜的推理工作也成為學術屆和工業界的一個重要研究課題。來自Mila人工智慧實驗室的瞿錳博士，給大家分享了他們在圖譜推理任務方向的一個研究：基於邏輯規則的圖譜推理（RNNLogic: Learning Lo ...
  • MySQL 數據備份與恢復
    數據備份 1. 備份資料庫 使用 mysqldump 命令可以將資料庫中的數據備份成一個文本文件，表的結構和數據以 SQL 的形式將存儲生成的文本文件 mysqldump -u username -p dbname>BackupName.sql 其中，dbname 代表資料庫名稱，BackupNam ...
一周排行
    -Advertisement-
    Play Games
  • 移動開發（一）：使用.NET MAUI開發第一個安卓APP
    移動開發（一）：使用.NET MAUI開發第一個安卓APP 對於工作多年的C#程式員來說，近來想嘗試開發一款安卓APP，考慮了很久最終選擇使用.NET MAUI這個微軟官方的框架來嘗試體驗開發安卓APP，畢竟是使用Visual Studio開發工具，使用起來也比較的順手，結合微軟官方的教程進行了安卓 ...
  • wpf ToggleButton選中效果和一個登錄界面
    前言 QuestPDF 是一個開源 .NET 庫，用於生成 PDF 文檔。使用了C# Fluent API方式可簡化開發、減少錯誤並提高工作效率。利用它可以輕鬆生成 PDF 報告、發票、導出文件等。 項目介紹 QuestPDF 是一個革命性的開源 .NET 庫，它徹底改變了我們生成 PDF 文檔的方 ...
  • 彈幕樹洞項目功能新增篇
    項目地址 項目後端地址： https://github.com/ZyPLJ/ZYTteeHole 項目前端頁面地址： ZyPLJ/TreeHoleVue (github.com) https://github.com/ZyPLJ/TreeHoleVue 目前項目測試訪問地址： http://tree ...
  • 第27篇 sqlserver2022詳細安裝步驟
    話不多說，直接開乾 一.下載 1.官方鏈接下載： https://www.microsoft.com/zh-cn/sql-server/sql-server-downloads 2.在下載目錄中找到下麵這個小的安裝包 SQL2022-SSEI-Dev.exe，運行開始下載SQL server； 二. ...
  • .NET 開源高性能 MQTT 類庫
    前言 隨著物聯網（IoT）技術的迅猛發展，MQTT（消息隊列遙測傳輸）協議憑藉其輕量級和高效性，已成為眾多物聯網應用的首選通信標準。 MQTTnet 作為一個高性能的 .NET 開源庫，為 .NET 平臺上的 MQTT 客戶端與伺服器開發提供了強大的支持。 本文將全面介紹 MQTTnet 的核心功能 ...
  • Serilog文檔翻譯系列（六） - 可用的接收器、增強器、格式化輸出
    Serilog支持多種接收器用於日誌存儲，增強器用於添加屬性，LogContext管理動態屬性，支持多種輸出格式包括純文本、JSON及ExpressionTemplate。還提供了自定義格式化選項，適用於不同需求。 ...
  • 警惕 Visual Studio 屬性求值副作用導致邏輯不符合預期
    目錄簡介獲取 HTML 文檔解析 HTML 文檔測試參考文章 簡介 動態內容網站使用 JavaScript 腳本動態檢索和渲染數據，爬取信息時需要模擬瀏覽器行為，否則獲取到的源碼基本是空的。 本文使用的爬取步驟如下： 使用 Selenium 獲取渲染後的 HTML 文檔 使用 HtmlAgility ...
  • [使用目前最新版]HybridCLR6.9.0+YooAsset2.2.4實現純C# Unity熱更新方案 (一)
    1.前言 什麼是熱更新 游戲或者軟體更新時，無需重新下載客戶端進行安裝，而是在應用程式啟動的情況下，在內部進行資源或者代碼更新 Unity目前常用熱更新解決方案 HybridCLR，Xlua，ILRuntime等 Unity目前常用資源管理解決方案 AssetBundles，Addressable， ...
  • 在 ASP.NET Core Web API 中使用操作篩選器統一處理通用操作
    本文章主要是在C# ASP.NET Core Web API框架實現向手機發送驗證碼簡訊功能。這裡我選擇是一個互億無線簡訊驗證碼平臺，其實像阿裡雲，騰訊雲上面也可以。 首先我們先去 互億無線 https://www.ihuyi.com/api/sms.html 去註冊一個賬號 註冊完成賬號後，它會送 ...
  • 第28篇 如何.net中實現高效可靠數據同步api
    通過以下方式可以高效，並保證數據同步的可靠性 1.API設計 使用RESTful設計，確保API端點明確，並使用適當的HTTP方法（如POST用於創建，PUT用於更新）。 設計清晰的請求和響應模型，以確保客戶端能夠理解預期格式。 2.數據驗證 在伺服器端進行嚴格的數據驗證，確保接收到的數據符合預期格 ...
所有分類