Windows下nginx的啟動，重啟，關閉功能

@echo off
rem 提供Windows下nginx的啟動，重啟，關閉功能
 
echo ==================begin========================
 
cls 
::ngxin 所在的盤符
set NGINX_PATH=E:
 
::nginx 所在目錄
set NGINX_DIR=E:\service\1\nginx-1.16.0\
color 0a 
TITLE Nginx 管理程式增強版
 
CLS 
 
echo. 
echo. ** Nginx 管理程式  *** 
echo. *** create 2019-09-10 *** 
echo. 
 
:MENU 
 
echo. ***** nginx 進程list ****** 
::tasklist|findstr /i "nginx.exe"
tasklist /fi "imagename eq nginx.exe"
 
echo. 
 
    if ERRORLEVEL 1 (
        echo nginx.exe不存在
    ) else (
        echo nginx.exe存在
    )
 
echo. 
::*************************************************************************************************************
echo. 
    echo.  [1] 啟動Nginx  
    echo.  [2] 關閉Nginx  
    echo.  [3] 重啟Nginx 
    echo.  [4] 刷新控制台  
    echo.  [5] 重新載入Nginx配置文件
    echo.  [6] 檢查測試nginx配置文件
    echo.  [7] 查看nginx version
    echo.  [0] 退 出 
echo. 
 
echo.請輸入選擇的序號:
set /p ID=
    IF "%id%"=="1" GOTO start 
    IF "%id%"=="2" GOTO stop 
    IF "%id%"=="3" GOTO restart 
    IF "%id%"=="4" GOTO MENU
    IF "%id%"=="5" GOTO reloadConf 
    IF "%id%"=="6" GOTO checkConf 
    IF "%id%"=="7" GOTO showVersion 
    IF "%id%"=="0" EXIT
PAUSE 
 
::*************************************************************************************************************
::啟動
:start 
    call :startNginx
    GOTO MENU
 
::停止
:stop 
    call :shutdownNginx
    GOTO MENU
 
::重啟
:restart 
    call :shutdownNginx
    call :startNginx
    GOTO MENU
 
::檢查測試配置文件
:checkConf 
    call :checkConfNginx
    GOTO MENU
 
::重新載入Nginx配置文件
:reloadConf 
    call :checkConfNginx
    call :reloadConfNginx
    GOTO MENU
    
::顯示nginx版本
:showVersion 
    call :showVersionNginx
    GOTO MENU   
    
    
::*************************************************************************************
::底層
::*************************************************************************************
:shutdownNginx
    echo. 
    echo.關閉Nginx...... 
    taskkill /F /IM nginx.exe > nul
    echo.OK,關閉所有nginx 進程
    goto :eof
 
:startNginx
    echo. 
    echo.啟動Nginx...... 
    IF NOT EXIST "%NGINX_DIR%nginx.exe" (
        echo "%NGINX_DIR%nginx.exe"不存在
        goto :eof
     )
 
    %NGINX_PATH% 
    cd "%NGINX_DIR%" 
 
    IF EXIST "%NGINX_DIR%nginx.exe" (
        echo "start '' nginx.exe"
        start "" nginx.exe
    )
    echo.OK
    goto :eof
    
 
:checkConfNginx
    echo. 
    echo.檢查測試 nginx 配置文件...... 
    IF NOT EXIST "%NGINX_DIR%nginx.exe" (
        echo "%NGINX_DIR%nginx.exe"不存在
        goto :eof
     )
 
    %NGINX_PATH% 
    cd "%NGINX_DIR%" 
    nginx -t -c conf/nginx.conf
 
    goto :eof
    
::重新載入 nginx 配置文件
:reloadConfNginx
    echo. 
    echo.重新載入 nginx 配置文件...... 
    IF NOT EXIST "%NGINX_DIR%nginx.exe" (
        echo "%NGINX_DIR%nginx.exe"不存在
        goto :eof
     )
 
    %NGINX_PATH% 
    cd "%NGINX_DIR%" 
    nginx -s reload
 
    goto :eof
    
::顯示nginx版本
:showVersionNginx
    echo. 
    %NGINX_PATH% 
    cd "%NGINX_DIR%" 
    nginx -V
    goto :eof