[oracle] Oracle存儲過程里操作BLOB的位元組數據的辦法，例如寫入32位整數

来源:https://www.cnblogs.com/zyl910/archive/2018/05/17/oracle_blob_raw_int32.html
-Advertisement-
Play Games

作者： "zyl910" 一、緣由 BLOB是指二進位大對象，也就是英文Binary Large Object的縮寫。 在很多時候，我們是通過其他編程語言（如Java）訪問BLOB的位元組數據，進行位元組級的操作的。 但是有些時候工作量很小，感覺專門為BLOB位元組級操作而專門開發個程式，是比較麻煩的。於 ...


作者： zyl910

一、緣由

BLOB是指二進位大對象，也就是英文Binary Large Object的縮寫。
在很多時候，我們是通過其他編程語言（如Java）訪問BLOB的位元組數據，進行位元組級的操作的。
但是有些時候工作量很小，感覺專門為BLOB位元組級操作而專門開發個程式，是比較麻煩的。於是我研究了一下如何直接在Oracle存儲過程里操作BLOB的位元組數據。

二、辦法

2.1 基本操作

使用 length 函數，可以獲取blob的位元組長度。如 v_len := length(i_blob); 。
與字元串（如 varchar2 等）一樣，blob為 null 時，length的返回值是 null。故建議加上 nvl 做一下轉換，如 v_len := nvl(length(i_blob), 0); 。

為了避免 null 問題，可使用 empty_blob 函數，它的作用是返回一個長度為0的blob。如 v_blob := empty_blob(); 。

empty_blob返回的blog只是一個初始化，它是不能修改位元組數據的。於是需要使用 dbms_lob.createtemporary 來創建一個能進行位元組數據操作的臨時blob。如 dbms_lob.createtemporary(v_blob, TRUE); 。

2.2 DBMS_LOB包

為了便於BLOB類型的使用，Oracle官方提供了 DBMS_LOB 包，它提供了很多工具函數。例如先前我們使用了createtemporary函數。
DBMS_LOB所提供的過程有——

  • APPEND：將源LOB中的內容加到目的LOB中。
  • CLOSE：關閉已經打開的LOB。
  • CREATETEMPORARY：在用戶的臨時表空間中，建立臨時LOB。
  • FILECLOSE：關閉打開的BFILE定位符所指向的OS文件。
  • FILECLOSEALL：關閉當前會話已經打開的所有BFILE文件。
  • FILEEXISTS：確定file_loc對應的OS文件是否存在，1：存在。0：不存在。
  • FILEGETNAME：獲取BFILE定位符所對應的目錄別名和文件名。
  • FILEISOPEN：確定BFILE對應的OS文件是否打開。
  • FREETEMPORARY：釋放在預設臨時表空間中的臨時LOB。
  • FILEOPEN：打開文件。
  • GETCHUNKSIZE：當建立包含CLOB/BLOB列的表時，通過指定CHUNK參數可以指定操縱LOB需要分配的位元組數（資料庫尺寸的整數倍）預設為數據塊的尺寸。
  • COPY：從源LOB中複製數據到目的LOB。
  • ERASE：刪除LOB中全部或部分內容。
  • TRIM：將LOB值減少到指定的長度。
  • WRITE：向LOB中寫入數據。
  • INSTR：返回特定樣式數據從LOB某偏移位置開始出現N次的具體位置。
  • IDOPEN：確定LOB是否打開，打開：1，未打開：0。
  • ISTEMPORARY：確定定位符是否為臨時LOB。
  • LOADFROMFILE：將BFILE的部分或全部內容複製到目標LOB變數。
  • LOADBLOBFROMFILE：將BFILE數據裝載到BLOB中，並且在裝載後取得最新的偏移位置。
  • OPEN：打開LOB，open_mode（只讀：dbms_lob.lob_readonly，寫：dbms_lob.lob_readwrite）。
  • COMPARE：比較兩個同種數據類型的LOB的部分或全部值是否相同。
  • GETLENGTH：獲取LOB的長度。
  • READ：從LOB中讀出數據。
  • SUBSTR：與字元處理函數SUBSTR使用方法一樣。
  • WRITEAPPEND：將緩衝區數據寫到LOB尾部。

有了DBMS_LOB包後，對於（變數級的）BLOB操作就比較方便了。例如我們想將兩個blob的內容，連續拼接到1個blob中，則可以這樣做——

  function test_blob_join(i_blob1 in blob, i_blob2 in blob) return blob is
    v_rt blob := empty_blob();
  begin
    dbms_lob.createtemporary(v_rt, TRUE);  -- 分配臨時的 blob .
    dbms_lob.append(v_rt, i_blob1);        -- 拼接 i_blob1 .
    dbms_lob.append(v_rt, i_blob2);        -- 拼接 i_blob2 .
    return v_rt;
  end;

可這樣測試——

select PKG_FINGER.test_blob_join(hextoraw('0102'), hextoraw('A1A2')) from dual;

它返回blob的位元組數據是 01 02 A1 A2。驗證通過。

2.3 位元組級操作與RAW數據類型

現在對實現BLOB的的變數級操作是沒有問題了。那麼，該怎樣實現BLOB的位元組級操作呢？
例如——怎麼從blob中截取位置開始的一串位元組？在blob中替換每個位置的位元組？在blob的最後追加位元組數據？
其實dbms_lob的 substr、write、writeappend 可分別解決這3個問題。
然後仔細一看，會發現這些過程使用了 RAW 類型。
對於RAW類型，很多資料是這樣說的——

RAW類型是Oracle中用於保存位串的一種數據類型，類似於CHAR，使用RAW（L) 方式聲明，最長可達32767位元組。

RAW與BLOB的關係——

  • BLOB中的一段位元組數據，就是RAW類型的。例如通過 dbms_lob.substr 截取得到的數據。
  • 其次可根據 RAW數據 去替換BLOB中的某段位元組數據。即使用 dbms_lob.write 。
  • 可在BLOB的最後追加 RAW數據 。即使用 dbms_lob.writeappend 。
  • Oracle支持 RAW 隱式轉型為 BLOB 類型。

觀察dbms_lob的幫助文檔，會發現每個函數既有BLOB版，又有CLOB版。而且，CLOB版用VARCHAR2類型時，其BLOB版是RAW類型。即 RAW與VARCHAR2 是類似的，一個是位元組串，一個是字元串。
許多常用的字元串函數也對 RAW 是有效的。例如 length 與 sustr 。

RAW 可用十六進位字元串來表示。所以一般使用 hextoraw 函數，將十六進位字元串轉為RAW。例如 hextoraw('A1A2') 。
RAW 可看作十六進位字元串。所以對raw變數使用length函數時，其返回值是 位元組長度的2倍（因為對於十六進位字元串，一個位元組是用2個十六進位字元表示的）。substr 等函數也存在同樣的情況。
還可以用 rawtohex，將 RAW類型的數據 轉換為 十六進位字元串（VARCHAR2）。

2.4 UTL_RAW包

上面提到 RAW 的length結果是 位元組長度的2倍，它是不太方便的。這時可以使用 UTL_RAW包。例如 utl_raw.length的結果就是 位元組長度。
常見的UTL_RAW過程有——

  • length：長度計算函數，得到一個raw類型變數的長度，單位為位元組
  • concat：拼接函數，用於拼接兩個raw類型變數
  • substr：獲取子串函數
  • bit_and：位與函數
  • bit_or：位或函數
  • bit_xor：位異或函數
  • overlay：給指定位元組賦值
  • cast_to_raw：字元串 轉 RAW
  • cast_to_varchar2：RAW 轉 varchar2
  • cast_to_nvarchar2：RAW 轉 nvarchar2
  • cast_to_number：RAW 轉 number
  • cast_from_number：number 轉 RAW
  • cast_to_binary_integer：RAW 轉 binary_integer
  • cast_from_binary_integer：binary_integer 轉 RAW

三、使用心得

3.1 32位整數轉換函數

最開始不知道 binary_integer就是32位整數。於是自己寫了32位整數與 RAW 的轉換函數。雖然現在用不上了，但覺得它們還是很適合作為應用示範的。

  -- 將數字轉為 raw(4)類型的 大端方式32位整數 .
  function TO_INT32BE(i_src in number) return raw is
    v_src number;
    v_hexstr varchar2(20);
    v_rt raw(4);
  begin
    v_src := i_src;
    if (v_src<0) then
      v_src:=v_src + 4294967296;    -- 為了支持負數.
    end if;
    v_hexstr := '0000000' || trim(to_char(v_src,'XXXXXXXX'));
    v_hexstr := substr(v_hexstr, length(v_hexstr)-7, length(v_hexstr));
    v_rt := hextoraw(v_hexstr);
    return v_rt;
  end;
  
  -- 將數字轉為 raw(4)類型的 小端方式32位整數 .
  function TO_INT32LE(i_src in number) return raw is
    v_src number;
    v_hexstr varchar2(20);
    v_rt raw(4);
  begin
    v_src := i_src;
    if (v_src<0) then
      v_src:=v_src + 4294967296;    -- 為了支持負數.
    end if;
    v_hexstr := '0000000' || trim(to_char(v_src,'XXXXXXXX'));
    v_hexstr := substr(v_hexstr, length(v_hexstr)-7, length(v_hexstr));
    v_hexstr := substr(v_hexstr, 7, 2)
      || substr(v_hexstr, 5, 2)
      || substr(v_hexstr, 3, 2)
      || substr(v_hexstr, 1, 2)
      ;
    v_rt := hextoraw(v_hexstr);
    return v_rt;
  end;
  
  -- 將 存儲在raw(4)中的大端方式32位整數 轉為數字. 值域為 0~4294967295 .
  function FROM_INT32BE(i_src in raw) return number is
    v_src raw(8);
    v_hexstr varchar2(20):='';
    v_rt number:=0;
  begin
    if ( (nvl(length(i_src), 0)<=0) ) then
      return v_rt;
    end if;
    if (length(i_src) >= 8) then    -- length、substr均把 raw 的1個位元組看作 2個（十六進位）字元.
      v_src := substr(i_src, 1, 8);
      v_hexstr := rawtohex(v_src);
    else
      v_hexstr := '000000' || rawtohex(i_src);
      v_hexstr := substr(v_hexstr, length(v_hexstr)-7, length(v_hexstr));
    end if;
    v_rt := to_number(v_hexstr,'XXXXXXXX');
    return v_rt;
  end;
  
  -- 將 存儲在raw(4)中的小端方式32位整數 轉為數字. 值域為 0~4294967295 .
  function FROM_INT32LE(i_src in raw) return number is
    v_src raw(8);
    v_hexstr varchar2(20):='';
    v_rt number:=0;
  begin
    if ( (nvl(length(i_src), 0)<=0) ) then
      return v_rt;
    end if;
    if (length(i_src) >= 8) then    -- length、substr均把 raw 的1個位元組看作 2個（十六進位）字元.
      v_src := substr(i_src, 1, 8);
      v_hexstr := rawtohex(v_src);
    else
      v_hexstr := rawtohex(i_src) || '000000';
      v_hexstr := substr(v_hexstr, 1, 8);
    end if;
    v_hexstr := substr(v_hexstr, 7, 2)
      || substr(v_hexstr, 5, 2)
      || substr(v_hexstr, 3, 2)
      || substr(v_hexstr, 1, 2)
      ;
    v_rt := to_number(v_hexstr,'XXXXXXXX');
    return v_rt;
  end;

3.2 將32位整數追加到blob

很多時候需要給blob追加一個 32位整數。現在利用上面的函數，可以這樣做——

      v_tempraw := TO_INT32LE(nvl(i_int32, 0));
      dbms_lob.writeappend(v_blob, 4, v_tempraw);

（完）

參考文獻


您的分享是我們最大的動力!

-Advertisement-
Play Games
更多相關文章
  • linux常用命令2
    這裡介紹的是linux比較高級的東西，如：用戶管理、用戶組管理、文件管理等。 ...
  • NFS 系統的搭建
    問題： 由於工作，需要，不斷得進行掛在硬碟重裝系統，NFS 系統給了我一個很好的解決方案。於是決定寫一篇博客，防止以後再次使用的時候，能夠很快得重新建立NFS 文件系統。 調研： NFS（Network File System）即網路文件系統，是FreeBSD支持的文件系統中的一種，它允許網路中的計 ...
  • Windows驅動開發入門指引
    1. 前言 因工作上項目的需要，筆者需要做驅動相關的開發，之前並沒有接觸過相關的知識，折騰一段時間下來，功能如需實現了，也積累了一些經驗和看法，所以在此做番總結。 對於驅動開發的開髮指引，微軟官方文檔網站已經提供了很詳細的教程文檔，並且在Github上提供了一系列典型的常式源碼用於開發人員參考。開發 ...
  • Linux內核同步機制之completion【轉】
    "Linux內核同步機制之completion" 內核編程中常見的一種模式是，在當前線程之外初始化某個活動，然後等待該活動的結束。這個活動可能是，創建一個新的內核線程或者新的用戶空間進程、對一個已有進程的某個請求，或者某種類型的硬體動作，等等。在這種情況下，我們可以使用信號量來同步這兩個任務。然而， ...
  • 第八章 計時器（BEEPER1）
    1 * 2 BEEPER1.C -- Timer Demo Program No.1 3 (c) Charles Petzold, 1998 4 */ 5 6 #include <Windows.h> 7 8 #define ID_TIMER 1 9 10 LRESULT CALLBACK WndP ...
  • (細節)My SQL中主鍵為0和主鍵自排約束的關係
    開始不設置主鍵 表的設計如下： 如果id的位置有好幾個0的話：設置主鍵並且自動排序時，0會從1開始遞增； Insert 進去 id = 0的數據，數據會從實際的行數開始增加，和從0變化不一樣； 現在主鍵是沒有0的，如果把某個id改成0的話，0不會變！直接會進行排序； 再insert一個id=0的看看 ...
  • 一次快速改寫 SQL Server 高效查詢的範例
    最近線上系統突然出現匯出資料超過 10 筆時，查詢逾時的狀況，在仔細查找之後。 發現了問題原因，透過應用端與數據端兩邊同時調整，將查詢的效率提昇了約數百倍以上 首先，原本應用端的商務邏輯為每一分頁筆數固定為10筆，所以使用者最多可以匯出 10 筆資料 而且原本的商務邏輯是寫成這樣的 這段語法在 SQ ...
  • 伺服器 'xxxx' 已被定義為分發伺服器。若要將該伺服器重新配置為分發伺服器，必須首先卸載現有的分發服務
    使用AWS DMS（Database Migration Service）將SQL Server資料庫同步到AWS的Data Lake上，需要在本地源資料庫上配置複製，在配置分發嚮導最後一步時，遇到下麵錯誤： TITLE: Microsoft.SqlServer.ConnectionInfo----... ...
一周排行
    -Advertisement-
    Play Games
  • 移動開發（一）：使用.NET MAUI開發第一個安卓APP
    移動開發（一）：使用.NET MAUI開發第一個安卓APP 對於工作多年的C#程式員來說，近來想嘗試開發一款安卓APP，考慮了很久最終選擇使用.NET MAUI這個微軟官方的框架來嘗試體驗開發安卓APP，畢竟是使用Visual Studio開發工具，使用起來也比較的順手，結合微軟官方的教程進行了安卓 ...
  • wpf ToggleButton選中效果和一個登錄界面
    前言 QuestPDF 是一個開源 .NET 庫，用於生成 PDF 文檔。使用了C# Fluent API方式可簡化開發、減少錯誤並提高工作效率。利用它可以輕鬆生成 PDF 報告、發票、導出文件等。 項目介紹 QuestPDF 是一個革命性的開源 .NET 庫，它徹底改變了我們生成 PDF 文檔的方 ...
  • 彈幕樹洞項目功能新增篇
    項目地址 項目後端地址： https://github.com/ZyPLJ/ZYTteeHole 項目前端頁面地址： ZyPLJ/TreeHoleVue (github.com) https://github.com/ZyPLJ/TreeHoleVue 目前項目測試訪問地址： http://tree ...
  • 第27篇 sqlserver2022詳細安裝步驟
    話不多說，直接開乾 一.下載 1.官方鏈接下載： https://www.microsoft.com/zh-cn/sql-server/sql-server-downloads 2.在下載目錄中找到下麵這個小的安裝包 SQL2022-SSEI-Dev.exe，運行開始下載SQL server； 二. ...
  • .NET 開源高性能 MQTT 類庫
    前言 隨著物聯網（IoT）技術的迅猛發展，MQTT（消息隊列遙測傳輸）協議憑藉其輕量級和高效性，已成為眾多物聯網應用的首選通信標準。 MQTTnet 作為一個高性能的 .NET 開源庫，為 .NET 平臺上的 MQTT 客戶端與伺服器開發提供了強大的支持。 本文將全面介紹 MQTTnet 的核心功能 ...
  • Serilog文檔翻譯系列（六） - 可用的接收器、增強器、格式化輸出
    Serilog支持多種接收器用於日誌存儲，增強器用於添加屬性，LogContext管理動態屬性，支持多種輸出格式包括純文本、JSON及ExpressionTemplate。還提供了自定義格式化選項，適用於不同需求。 ...
  • 警惕 Visual Studio 屬性求值副作用導致邏輯不符合預期
    目錄簡介獲取 HTML 文檔解析 HTML 文檔測試參考文章 簡介 動態內容網站使用 JavaScript 腳本動態檢索和渲染數據，爬取信息時需要模擬瀏覽器行為，否則獲取到的源碼基本是空的。 本文使用的爬取步驟如下： 使用 Selenium 獲取渲染後的 HTML 文檔 使用 HtmlAgility ...
  • [使用目前最新版]HybridCLR6.9.0+YooAsset2.2.4實現純C# Unity熱更新方案 (一)
    1.前言 什麼是熱更新 游戲或者軟體更新時，無需重新下載客戶端進行安裝，而是在應用程式啟動的情況下，在內部進行資源或者代碼更新 Unity目前常用熱更新解決方案 HybridCLR，Xlua，ILRuntime等 Unity目前常用資源管理解決方案 AssetBundles，Addressable， ...
  • 在 ASP.NET Core Web API 中使用操作篩選器統一處理通用操作
    本文章主要是在C# ASP.NET Core Web API框架實現向手機發送驗證碼簡訊功能。這裡我選擇是一個互億無線簡訊驗證碼平臺，其實像阿裡雲，騰訊雲上面也可以。 首先我們先去 互億無線 https://www.ihuyi.com/api/sms.html 去註冊一個賬號 註冊完成賬號後，它會送 ...
  • 第28篇 如何.net中實現高效可靠數據同步api
    通過以下方式可以高效，並保證數據同步的可靠性 1.API設計 使用RESTful設計，確保API端點明確，並使用適當的HTTP方法（如POST用於創建，PUT用於更新）。 設計清晰的請求和響應模型，以確保客戶端能夠理解預期格式。 2.數據驗證 在伺服器端進行嚴格的數據驗證，確保接收到的數據符合預期格 ...
所有分類