關於游標，首先要知道游標的定義。 游標，是記憶體中的一款區域，用來存放select的結果集 游標用來處理從資料庫中檢索的多行記錄（使用select語句）。利用游標，程式可以逐個的處理和遍歷一次索引返回的整個記錄集。 在資料庫中，存在兩種游標： 一、顯示游標（需要明確定義） 顯示游標被用於處理返回多行數 ...
關於游標，首先要知道游標的定義。
游標，是記憶體中的一款區域，用來存放select的結果集
游標用來處理從資料庫中檢索的多行記錄（使用select語句）。利用游標，程式可以逐個的處理和遍歷一次索引返回的整個記錄集。
在資料庫中，存在兩種游標：
一、顯示游標（需要明確定義）
顯示游標被用於處理返回多行數據的select語句，游標名通過CURSOR...IS語句顯示的賦給select語句。
在PL/SQL中處理顯示游標的四個步驟：
1）聲明游標：CURSOR IS select語句
2）為查詢打開游標： OPEN 游標名稱
3） 取得結果放入PL/SQL變數中：
FETCH 游標名稱 INTO list_of_variables;
FETCH 游標名稱 INTO PL/SQL_record;
4）關閉游標：CLOSE 游標名稱
註意：在聲明游標時， select語句不能包含INTO子句。當使用顯示游標時，INTO子句是FETCH語句的一部分。
二、隱式游標
所有的隱式游標都被假設為只返回一條記錄。
使用隱式游標時，用戶無需進行聲明、打開及關閉。PL/SQL隱含地打開、處理，然後關掉游標。
例如：
…….
SELECT studentNo,studentName
INTO curStudentNo,curStudentName
FROM StudentRecord
WHERE name=’gg’;
上述游標自動打開，並把相關值賦給對應變數，然後關閉。執行完後，PL/SQL變數curStudentNo,curStudentName中已經有了值。
2、 隱式游標
單條sql語句所產生的結果集合
用關鍵字SQL表示隱式游標
4個屬性 %rowcount 影響的記錄的行數 整數
%found 影響到了記錄 true
%notfound 沒有影響到記錄 true
%isopen 是否打開 布爾值 永遠是false
多條sql語句 隱式游標SQL永遠指的是最後一條sql語句的結果
主要使用在update 和 delete語句上
實際操作和例子：
(1)FOR迴圈游標 (常用的一種游標)
--<1>定義游標
--<2>定義游標變數
--<3>使用for迴圈來使用這個游標
--前向游標 只能往一個方向走
--效率很高
declare
--類型定義
cursor cc is select empno,ename,job,sal
from emp where job = 'MANAGER';
--定義一個游標變數
ccrec cc%rowtype;
begin
--for迴圈
for ccrec in cc loop
dbms_output.put_line(ccrec.empno||'-'||ccrec.ename||'-'||ccrec.job||'-'||ccrec.sal);
end loop;
end;
(2) fetch游標
--使用的時候 必須要明確的打開和關閉
declare
--類型定義
cursor cc is select empno,ename,job,sal
from emp where job = 'MANAGER';
--定義一個游標變數
ccrec cc%rowtype;
begin
--打開游標
open cc;
--loop迴圈
loop
--提取一行數據到ccrec中
fetch cc into ccrec;
--判斷是否提取到值，沒取到值就退出
--取到值cc%notfound 是false
--取不到值cc%notfound 是true
exit when cc%notfound;
dbms_output.put_line(ccrec.empno||'-'||ccrec.ename||'-'||ccrec.job||'-'||ccrec.sal);
end loop;
--關閉游標
close cc;
end;
游標的屬性4種
%notfound fetch是否提到數據 沒有true 提到false
%found fetch是否提到數據 有true 沒提到false
%rowcount 已經取出的記錄的條數
%isopen 布爾值 游標是否打開
(3)參數游標
按部門編號的順序輸出部門經理的名字
declare
--部門
cursor c1 is select deptno from dept;
--參數游標c2,定義參數的時候
--只能指定類型,不能指定長度
--參數只能出現在select語句=號的右側
cursor c2(no number,pjob varchar2) is select emp.* from emp
where deptno = no and job=pjob;
c1rec c1%rowtype;
c2rec c2%rowtype;
--定義變數的時候要指定長度
v_job varchar2(20);
begin
--部門
for c1rec in c1 loop
--參數在游標中使用
for c2rec in c2(c1rec.deptno,'MANAGER') loop
dbms_output.put_line(c1rec.deptno||'-'||c2rec.ename);
end loop;
end loop;
end;
(4)引用游標/動態游標
-- select語句是動態的
declare
--定義一個類型(ref cursor)弱類型
type cur is ref cursor;
--強類型(返回的結果集有要求)
type cur1 is ref cursor return emp%rowtype;
--定義一個ref cursor類型的變數
cura cur;
c1rec emp%rowtype;
c2rec dept%rowtype;
begin
DBMS_output.put_line('輸出員工') ;
open cura for select * from emp;
loop
fetch cura into c1rec;
exit when cura%notfound;
DBMS_output.put_line(c1rec.ename) ;
end loop ;
DBMS_output.put_line('輸出部門') ;
open cura for select * from dept;
loop
fetch cura into c2rec;
exit when cura%notfound;
DBMS_output.put_line(c2rec.dname) ;
end loop;
close cura;
end;
