步驟 0 uboot 將 zImage 複製到記憶體之後，跳轉到 zImage 處開始執行，首先執行的代碼是 arch/arm/boot/compressed/head.S 文件，首先是一些涉及不同體繫結構調試相關的彙編巨集定義 ifdef DEBUG if defined(CONFIG_DEBUG_I ...
步驟 0
uboot 將 zImage 複製到記憶體之後，跳轉到 zImage 處開始執行，首先執行的代碼是
arch/arm/boot/compressed/head.S 文件，首先是一些涉及不同體繫結構調試相關的彙編巨集定義
#ifdef DEBUG
#if defined(CONFIG_DEBUG_ICEDCC)
#if defined(CONFIG_CPU_V6) || defined(CONFIG_CPU_V6K) || defined(CONFIG_CPU_V7)
.macro loadsp, rb, tmp
.endm
.macro writeb, ch, rb
mcr p14, 0, \ch, c0, c5, 0
.endm
... 省略 ...
#endif
#endif
#endif
步驟 1
首先是保存 bootloader 傳遞過來的機器 ID 和 atags 起始地址
@ 設置段名
.section ".start", #alloc, #execinstr
.align
.arm @ 設置指令為 arm 模式
start:
.type start,#function @ 聲明為函數標簽
.rept 7
mov r0, r0
.endr
ARM( mov r0, r0 )
ARM( b 1f ) @ 向下跳轉
THUMB( adr r12, BSYM(1f) )
THUMB( bx r12 )
.word 0x016f2818 @ Magic numbers to help the loader
.word start @ 程式其實地址，即 zImage 的地址
.word _edata @ zImage 結束地址
THUMB( .thumb )
1: mov r7, r1 @ 保存 bootloader 傳遞過來的機器 ID
mov r8, r2 @ 保存 bootloader 傳遞過來的 atags 起始地址
步驟 2
關閉中斷、進入 SVC 模式
#ifndef __ARM_ARCH_2__
mrs r2, cpsr @ get current mode
tst r2, #3 @ not user?
bne not_angel
mov r0, #0x17 @ 進入 SVC 模式
ARM( swi 0x123456 ) @ angel_SWI_ARM
THUMB( svc 0xab ) @ angel_SWI_THUMB
not_angel:
mrs r2, cpsr
orr r2, r2, #0xc0 @ 關閉 FIQ 和 IRQ
msr cpsr_c, r2
#else
teqp pc, #0x0c000003 @ turn off interrupts
步驟 3
為了加速解壓過程，打開緩存
#ifdef CONFIG_AUTO_ZRELADDR
@ 如果配置了運行時自動計算重定位地址
@ 則根據當前 pc 位置和 TEXT_OFFSET 計算出解壓位置
@ TEXT_OFFSET 在 arch/arm/Makefile 中指定，表示的是相對於記憶體起始地址的偏移
@ 定義為 textofs-y := 0x00008000 TEXT_OFFSET := $(textofs-y)
mov r4, pc
and r4, r4, #0xf8000000 @ 這裡假設 zImage 是被放在記憶體的前 128MB 內的
add r4, r4, #TEXT_OFFSET @ 得到 zImage 解壓的物理地址
#else
@ 這裡是直接在 arch/arm/mach-s5p4418/Makefile.boot 中定義的
@ 定義為 zreladdr-y := 0x40008000
ldr r4, =zreladdr @ r4 存放解壓後內核存放的起始地址
#endif
@ 打開緩存和 MMU
bl cache_on
步驟 4
檢查解壓後的內核鏡像是否與當前鏡像發生覆蓋
restart: adr r0, LC0
ldmia r0, {r1, r2, r3, r6, r10, r11, r12} @ 將 LC0 數據放入寄存器中
ldr sp, [r0, #28] @ 更新棧指針位置
sub r0, r0, r1 @ 計算當前程式位置和鏈接地址間的偏移量
add r6, r6, r0 @ 得到 zImage 運行地址的結束位置
add r10, r10, r0 @ 存放未壓縮內核大小的運行地址
/*
* 內核編譯系統會將未壓縮的內核大小追加到壓縮後的內核數據之後
* 並以小端格式存儲
*/
@ 取出未壓縮內核大小放入 r9
ldrb r9, [r10, #0]
ldrb lr, [r10, #1]
orr r9, r9, lr, lsl #8
ldrb lr, [r10, #2]
ldrb r10, [r10, #3]
orr r9, r9, lr, lsl #16
orr r9, r9, r10, lsl #24
#ifndef CONFIG_ZBOOT_ROM
/* 在棧指針之上分配記憶體空間放到 r10 中 (64k max) */
add sp, sp, r0
add r10, sp, #0x10000
#else
mov r10, r6
#endif
mov r5, #0 @ init dtb size to 0
/*
* 檢查解壓後的內核是否會覆蓋當前代碼
* r4 = 最終解壓後的內核起始地址
* r9 = 解壓後的內核鏡像大小
* r10 = 當前鏡像結束地址，其中包括所分配的記憶體區域
* We basically want:
* r4 - 16k 頁表 >= r10 -> OK
* r4 + image length <= address of wont_overwrite -> OK
*/
add r10, r10, #16384 @ 內核鏡像前的 16KB 頁表
cmp r4, r10
bhs wont_overwrite @ 解壓後的內核起始地址大於等於 r10
add r10, r4, r9
adr r9, wont_overwrite
cmp r10, r9 @ 或者解壓後的內核結束地址在 wont_overwrite 地址之前
bls wont_overwrite
/*
* r6 = _edata
* r10 = end of the decompressed kernel
*/
@ 當前代碼段向後移動到的目的地址，不足 256 位元組的補足 256 位元組，向上取整
add r10, r10, #((reloc_code_end - restart + 256) & ~255)
bic r10, r10, #255
@ 當前代碼段起始地址，以 32 位元組為單位，向下取整
adr r5, restart
bic r5, r5, #31
sub r9, r6, r5 @ 需要移動鏡像的大小
add r9, r9, #31 @ 以 32 位元組為單位向上取整
bic r9, r9, #31
add r6, r9, r5 @ 迴圈結束地址
add r9, r9, r10 @ 目的地址結束位置
@ 迴圈移動當前鏡像
1: ldmdb r6!, {r0 - r3, r10 - r12, lr}
cmp r6, r5
stmdb r9!, {r0 - r3, r10 - r12, lr}
bhi 1b
sub r6, r9, r6 @ 代碼重定位的偏移地址
#ifndef CONFIG_ZBOOT_ROM
add sp, sp, r6 @ 對棧指針也進行重定位
#endif
bl cache_clean_flush
@ 跳轉到重定位後的鏡像 restart 處重新執行，檢查是否存在覆蓋
adr r0, BSYM(restart)
add r0, r0, r6
mov pc, r0
步驟 5
清理 bss 段、解壓內核、關閉緩存，最後啟動內核
/* 至此，當前鏡像和解壓後的內核不會發生覆蓋問題 */
wont_overwrite:
/*
* If delta is zero, we are running at the address we were linked at.
* r0 = delta
* r2 = BSS start
* r3 = BSS end
* r4 = kernel execution address
* r5 = appended dtb size (0 if not present)
* r7 = architecture ID
* r8 = atags pointer
* r11 = GOT start
* r12 = GOT end
* sp = stack pointer
*/
orrs r1, r0, r5
beq not_relocated
add r11, r11, r0
add r12, r12, r0
not_relocated: mov r0, #0
1: str r0, [r2], #4 @ 清理 bss 段
str r0, [r2], #4
str r0, [r2], #4
str r0, [r2], #4
cmp r2, r3
blo 1b
/*
* 至此，C 語言運行環境已經初始化完成
* r4 = 解壓後的內核起始地址
* r7 = 機器 ID
* r8 = atags 指針
*/
mov r0, r4
mov r1, sp @ 在棧指針之上分配記憶體空間
add r2, sp, #0x10000 @ 64k max
mov r3, r7
bl decompress_kernel @ 解壓內核
bl cache_clean_flush
bl cache_off @ 關閉緩存
mov r0, #0 @ must be zero
mov r1, r7 @ restore architecture number
mov r2, r8 @ restore atags pointer
ARM( mov pc, r4 ) @ 啟動內核
THUMB( bx r4 ) @ entry point is always ARM
.align 2
.type LC0, #object
LC0: .word LC0 @ r1：LC0 的鏈接地址
.word __bss_start @ r2：bss 段的起始地址
.word _end @ r3：bss 段的結束地址
.word _edata @ r6：zImage 的結束地址
.word input_data_end - 4 @ r10：存放未壓縮的內核大小的鏈接地址
.word _got_start @ r11：全局偏移表起始位置
.word _got_end @ ip：全局偏移表結束位置
.word .L_user_stack_end @ sp：棧指針
.size LC0, . - LC0 @ 該 LC0 數據的大小
