sql某個日期是當年的第幾周

/*
*周一作為一周的開始
*當年的1月1號所在的周算作第一周
*/
CREATE function GetWeekIndexFirstDate
(
   @date datetime
)
returns int
as
begin
 
/*
*計算邏輯
*1.先找出當年的1月1號@firstDate
*2.計算出當年的第一個周日@firstSunday
*3.以@firstSunday為分界線，@firstSunday前面的算作第一周，@firstSunday後面的通過除7再加1，來計算周數
*/
 
   declare @index int;
   declare @firstDate datetime;--當年的1月1號
   declare @firstSunday datetime;--當年的第一個周日
   declare @firstWeekSunday datetime;--當年的第一周的周日
 
   set @firstDate = convert(datetime,convert(varchar(4),Year(@date)) + '-1-1')
 
   set @firstSunday = case when datepart(dw,@firstDate)=1 then @firstDate else dateadd(dd,8-datepart(dw,@firstDate),@firstDate) end;
 
   if(@date<=@firstSunday)
      set  @index = 1;
   else
      set @index = ceiling(datediff(dd,@firstSunday,@date)/7.0)+1
 
   return @index;
end



 
 
/*
*周一作為一周的開始
*當年的第一個周一所在的周算作第一周
*/
CREATE function GetWeekIndexFirstMonday
(
   @date datetime
)
returns int
as
begin
 
 
 
/*
*計算邏輯
*1.先找出當年的1月1號@firstDate
*2.計算出當年的第一個周一@firstMonday
*3.以@firstMonday為分界線，@firstMonday前面的算作上一年的最後一周，@firstMonday後面的通過除7再加1，來計算周數
*/
 
   declare @index int;
   declare @firstDate datetime;--當年的1月1號
   declare @firstMonday datetime;--當年的第一個周一
   declare @lastYearFirstDate datetime;--上一年的1月1號
   declare @lastYearFirstMonday datetime;--上一年的第一個周一
 
   select @firstDate = convert(datetime,convert(varchar(4),Year(@date)) + '-1-1')
      , @lastYearFirstDate = convert(datetime,convert(varchar(4),datepart(yyyy,@date)-1) + '-1-1')
 
   select @firstMonday = case when datepart(dw,@firstDate)<=2 then dateadd(dd,2-datepart(dw,@firstDate) ,@firstDate)
                      else dateadd(dd,9-datepart(dw,@firstDate),@firstDate) end
      ,@lastYearFirstMonday = case when datepart(dw,@lastYearFirstDate)<=2 then dateadd(dd,2-datepart(dw,@lastYearFirstDate) ,@lastYearFirstDate)
                      else dateadd(dd,9-datepart(dw,@lastYearFirstDate),@lastYearFirstDate) end;
 



   if(@date >=@firstMonday)
      set  @index = floor(datediff(dd,@firstMonday,@date)/7.0)+1;
   else
      set @index = floor(datediff(dd,@lastYearFirstMonday,@date)/7.0)+1
 
   return @index;
end