本節對Oracle中的游標進行詳細講解。

本節所舉實例來源Oracle中scott用戶下的emp表dept表：

一、游標：

1、概念：

游標的本質是一個結果集resultset，主要用來臨時存儲從資料庫中提取出來的數據塊。

二、游標的分類：

1、顯式游標：由用戶定義，需要的操作：定義游標、打開游標、提取數據、關閉游標，主要用於對查詢語句的處理。

屬性：%FOUND        %NOTFOUND        %ISOPEN          %ROWCOUNT

Example:列印emp表的員工信息

DECLARE
  CURSOR emp_cursor IS SELECT empno,ename,job FROM emp;
  v_empno emp.empno%TYPE;
  v_name emp.ename%TYPE;
  v_job emp.job%TYPE;
BEGIN
  OPEN emp_cursor;
  LOOP
    FETCH emp_cursor INTO v_empno,v_name,v_job;
    DBMS_OUTPUT.PUT_LINE('員工號為:'||v_empno||'姓名是'||v_name||'職位：'||v_job);
    EXIT WHEN emp_cursor%NOTFOUND;
  END LOOP;
  CLOSE emp_cursor;
END; 

這裡嚴格按照顯示游標的書寫規則：DECLARE emp_cursor定義游標OPEN emp_cursor打開游標FETCH emp_cursor INTO...提取數據CLOSE emp_cursor關閉游標,因為提取出來的數據屬於多行，所以通過loop迴圈列印即可。

Example2:檢驗游標是否打開,如果打開顯示提取行數

DECLARE
  CURSOR emp_cursor IS SELECT empno,ename,job FROM emp;
  v_empno emp.empno%TYPE;
  v_name emp.ename%TYPE;
  v_job emp.job%TYPE;
BEGIN
  OPEN emp_cursor;
  LOOP
       FETCH emp_cursor INTO v_empno,v_name,v_job;
       EXIT WHEN emp_cursor%NOTFOUND;
  END LOOP;
  IF emp_cursor%ISOPEN THEN
    DBMS_OUTPUT.PUT_LINE('游標已打開');
    DBMS_OUTPUT.PUT_LINE('讀取了'||emp_cursor%ROWCOUNT||'行');
  ELSE
    DBMS_OUTPUT.PUT_LINE('游標沒有打開');
  END IF;  
  CLOSE emp_cursor;
END;

通過%ISOPEN屬性判斷游標是否打開，%ROWCOUNT判斷獲取行數。

2、隱式游標：由系統定義併為它創建工作區域，並且隱式的定義打開提取關閉，隱式游標的游標名就是'SQL',屬性和顯示游標相同，主要用於對單行select語句或dml操作進行處理。

Example:又用戶輸入員工號修改員工工資如成功則列印輸出成功標誌。

為了儘量不改變原表，創建新表emp_new和原表數據相同：

CREATE TABLE emp_new
AS
SELECT * FROM emp;

BEGIN
  UPDATE emp_new SET sal = sal+500 WHERE empno=&empno;
  IF SQL%FOUND THEN
    DBMS_OUTPUT.PUT_LINE('成功修改');
    COMMIT;
  ELSE
    DBMS_OUTPUT.PUT_LINE('修改失敗');
    ROLLBACK;
  END IF;
END;

這裡註意增刪改以後要對做的操作進行commit提交，如果操作失敗則rollback回滾剛纔的操作。

3、參數游標：

在定義游標時加入參數的游標，可以配合游標for迴圈快速找到需要的數據。這裡先講一下游標for迴圈

A、游標FOR迴圈：

隱含的執行了打開提取關閉數據，代碼精簡很多。Expression:

FOR table_record IN table_cursor LOOP

　　STATEMENT;

END LOOP;

 Example:使用游標For迴圈列印輸出員工信息：

DECLARE
CURSOR emp_cursor IS SELECT empno,ename,job FROM emp;
BEGIN
  FOR emp_record IN emp_cursor LOOP
    DBMS_OUTPUT.PUT_LINE('員工號：'||emp_record.empno||'員工姓名'||emp_record.ename||'員工職位'||emp_record.job);
  END LOOP;
END;

這裡游標FOR迴圈省去了對於取到的數據的變數的命名和賦值，同時如果全部列印則不用寫迴圈條件，代碼精簡了很多。

如果想讓代碼更加精簡，則可以去掉對游標的聲明引入子查詢即可，操作如下。

BEGIN
  FOR emp_record IN (SELECT empno,ename,job FROM emp) LOOP
    DBMS_OUTPUT.PUT_LINE('員工號：'||emp_record.empno||'員工姓名'||emp_record.ename||'員工職位'||emp_record.job);
  END LOOP;
END;

代碼更加精簡，得到的結果相同。和隱式游標是不是有點像，但隱式游標主要用於的是單行select和dml語句的操作，註意2者用法的區別。

下麵繼續參數游標的實例：

Example：輸入部門號列印員工信息：

DECLARE
CURSOR emp_cursor(dno NUMBER)IS SELECT empno,ename,job FROM emp WHERE deptno=dno;
BEGIN
  FOR emp_record IN emp_cursor(&dno) LOOP
    DBMS_OUTPUT.PUT_LINE('員工號'||emp_record.empno||'姓名'||emp_record.ename||'職位'||emp_record.job);
  END LOOP;
END;

這裡既然有參數，那麼必然會有對游標的聲明，在結合游標FOR迴圈快速超找所需要的數據。

三、使用游標修改數據的註意事項

1、使用游標修改數據時，為防止他人在自己操作數據時對數據進行修改，oracle提供for update子句進行加鎖。

同時在你使用update或delete時，必須使用where current of+name_cursor語句，以及在最後記得提交。如果

是級聯操作則可以使用for update of 來進行相關表的加鎖。

Example1：對職位是PRESIDENT的員工加1000工資，MANAGER的人加500工資

CREATE TABLE emp_new
AS
SELECT * FROM emp;

DECLARE
CURSOR empnew_cursor IS SELECT ename,job FROM emp_new FOR UPDATE;
BEGIN
  FOR empnew_record IN empnew_cursor LOOP
    DBMS_OUTPUT.PUT_LINE('姓名'||empnew_record.ename||'職位'||empnew_record.job);
    IF empnew_record.job='PRESIDENT' THEN
      UPDATE emp_new SET sal=sal+1000 WHERE CURRENT OF empnew_cursor;
    ELSIF empnew_record.job='MANAGER' THEN
      UPDATE emp_new SET sal=sal+500 WHERE CURRENT OF empnew_cursor;
    END IF;
  END LOOP;
  COMMIT;
END;

SELECT * FROM EMP WHERE job in('PRESIDENT','MANAGER');
SELECT * FROM EMP_NEW WHERE job in('PRESIDENT','MANAGER');

可以看到這裡工資有了相應的變化。

至此，Oracle游標解析完畢，總而言之，游標只是作為我們從資料庫中提取出來的一部分數據，我們針對這個結果集做一系列的操作。

　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　　2018-09-07    16:15:34