本文目錄列表：1、時間粒度有關描述2、時間維度有關功能函數3、日曆數據表4、日曆數據表數據填充5、總結語6、參考清單列表時間粒度有關描述將該系列涉及到的時間粒度以及分鐘以下的粒度做個總結，如以下表格：時間粒度納秒微妙毫秒秒分鐘日期分鐘數（整數）*日期分鐘*日內分鐘數小時日期小時數（整數）日期小時日內...
本文目錄列表： 1、時間粒度有關描述 2、時間維度有關功能函數
3、日曆數據表 4、日曆數據表數據填充 5、總結語 6、參考清單列表 時間粒度有關描述 將該系列涉及到的時間粒度以及分鐘以下的粒度做個總結，如以下表格：
| 時間粒度 | ||||||||
| 納秒 | ||||||||
| 微妙 | ||||||||
| 毫秒 | ||||||||
| 秒 | ||||||||
| 分鐘 | 日期分鐘數（整數）* | 日期分鐘* | 日內分鐘數 | |||||
| 小時 | 日期小時數（整數） | 日期小時 | 日內小時數 | |||||
| 天 | 日期天數（整數） | 日期天 | 周內日索引 | 旬內日索引 | 月內日索引 | 季內日索引 | 年內日索引 | 日期內日索引 |
| 周 | 日期周數（整數） | 日期周 | 旬內周索引 | 月內周索引 | 季內周索引 | 年內周索引 | 日期內周索引 | |
| 旬 | 日期旬數（整數） | 日期旬 | 月內旬索引 | 季內旬索引 | 年內旬索引 | 日期內旬索引 | ||
| 月 | 日期月數（整數） | 日期月 | 季內月索引 | 年內月索引 | 日期內月索引 | |||
| 季 | 日期季數（整數） | 日期季 | 年內季索引 | 日期內季索引 | ||||
| 年 | 日期年數（整數） | 日期年 | 日期內年索引 |
分鐘時間粒度有關函數，T-SQL代碼如下：
IF OBJECT_ID(N'dbo.ufn_Minutes', 'FN') IS NOT NULL
BEGIN
DROP FUNCTION dbo.ufn_Minutes;
END
GO
--==================================
-- 功能: 獲得指定的日期時間基於預設基準日期的總小時數(一個整數值）
-- 說明: 運行在SQL Server 2005 +。
-- 如果指定的日期時間為NULL或者小於預設基準日期時，則其值為預設基準日期。
-- 結果值為非負整數，從0開始計數。
-- 作者: XXX
-- 創建: yyyy-MM-dd
-- 修改: yyyy-MM-dd XXX 修改內容描述
-- 調用: SET @intMinutes = dbo.ufn_Minutes('5983-01-24 02:07:00.000');
--==================================
CREATE FUNCTION dbo.ufn_Minutes
(
@dtmDate DATETIME -- 指定的日期時間
) RETURNS INT
AS
BEGIN
RETURN DATEDIFF(MINUTE, dbo.ufn_GetDefaultBasedate(), dbo.ufn_GetValidDate(@dtmDate));
END
GO
IF OBJECT_ID(N'dbo.ufn_Minutes2Date', 'FN') IS NOT NULL
BEGIN
DROP FUNCTION dbo.ufn_Minutes2Date;
END
GO
--==================================
-- 功能: 獲得一個整數值基於預設基準日期對應的日期時間
-- 說明: 運行在SQL Server 2005+。
-- 如果指定的整數值為NULL或為負整數時，則其值預設為0。
-- 如果指定的整數值大於“5983-01-24 02:07:00”對應的整數值時，則其值預設設置為“5983-01-24 02:07:00”對應的整數值。
-- 結果值為基於預設基準日期開始計數的日期。
-- 作者: XXX
-- 創建: yyyy-MM-dd
-- 修改: yyyy-MM-dd XXX 修改內容描述
-- 調用: SET @dtmDate = dbo.ufn_Minutes2Date(947033) -- '2008-01-14 17:00'
--==================================
CREATE FUNCTION dbo.ufn_Minutes2Date
(
@intMinutes INT -- 指定的整數值
) RETURNS DATETIME
AS
BEGIN
SET @intMinutes = dbo.ufn_GetValidDateNum(@intMinutes);
DECLARE @intMinutesMax AS INT;
SET @intMinutesMax = dbo.ufn_Minutes('5983-01-24 02:07:00');
IF @intMinutes >= @intMinutesMax
BEGIN
SET @intMinutes = @intMinutesMax;
END
RETURN DATEADD(MINUTE, @intMinutes, dbo.ufn_GetDefaultBasedate());
END
GO
IF OBJECT_ID(N'dbo.ufn_MinutesOfDay', 'FN') IS NOT NULL
BEGIN
DROP FUNCTION dbo.ufn_MinutesOfDay;
END
GO
--==================================
-- 功能: 獲取指定的日期時間基於所在當前日午夜零時的分鐘數
-- 功能: 運行在SQL Server 2005+。
-- 結果值從0開始計數，包括0、1、2、3、1439。
-- 作者: XXX
-- 創建: yyyy-MM-dd
-- 修改: yyyy-MM-dd XXX 修改內容描述
-- 調用: SET @sintMinutesOfDay = dbo.fn_MinutesOfDay(GETDATE());
--==================================
CREATE FUNCTION dbo.ufn_MinutesOfDay
(
@dtmDate DATETIME -- 指定的日期時間
) RETURNS SMALLINT
AS
BEGIN
RETURN DATEPART(HOUR, @dtmDate) * 60 + DATEPART(MINUTE, @dtmDate);
END
GO
-- Test Code
DECLARE @dtmDate AS DATETIME;
SET @dtmDate = '2016-02-14 02:14:18';
SELECT
@dtmDate AS 'The Current DateTime'
,dbo.ufn_Minutes(@dtmDate) AS 'Minutes'
,dbo.ufn_Minutes2Date(dbo.ufn_Minutes(@dtmDate)) AS 'DateTime Mapping Minutes'
,dbo.ufn_MinutesOfDay(@dtmDate) AS 'Minutes Of The Current Day';
SET @dtmDate = '2016-05-20 05:20:48';
SELECT
@dtmDate AS 'The Current DateTime'
,dbo.ufn_Minutes(@dtmDate) AS 'Minutes'
,dbo.ufn_Minutes2Date(dbo.ufn_Minutes(@dtmDate)) AS 'DateTime Mapping Minutes'
,dbo.ufn_MinutesOfDay(@dtmDate) AS 'Minutes Of The Current Day';
GO
以上3個函數的測試效果，如下圖：
小時時間粒度有關函數，T-SQL代碼如下：
IF OBJECT_ID(N'dbo.ufn_Hours', 'FN') IS NOT NULL
BEGIN
DROP FUNCTION dbo.ufn_Hours;
END
GO
--==================================
-- 功能: 獲得指定的日期時間基於基準日期的總小時數(一個整數值）
-- 說明: 運行在SQL Server 2005+。
-- 如果指定的日期時間為NULL或者小於預設基準日期時，則其值為預設基準日期。
-- 結果值為非負整數，從0開始計數。
-- 作者: XXX
-- 創建: yyyy-MM-dd
-- 修改: yyyy-MM-dd XXX 修改內容描述
-- 調用: SET @intHours = dbo.ufn_Hours('2008-01-14 17:45') -- 947033
--==================================
CREATE FUNCTION dbo.ufn_Hours
(
@dtmDate DATETIME -- 指定的日期時間
) RETURNS INT
--$Encode$--
AS
BEGIN
RETURN DATEDIFF(HOUR, dbo.ufn_GetDefaultBasedate(), dbo.ufn_GetValidDate(@dtmDate));
END
GO
IF OBJECT_ID(N'dbo.ufn_Hours2Date', 'FN') IS NOT NULL
BEGIN
DROP FUNCTION dbo.ufn_Hours2Date;
END
GO
--==================================
-- 功能: 獲得一個整數值基於基準日期對應的日期時間
-- 說明: 運行在SQL Server 2005+。
-- 如果指定的整數值為NULL或為負整數時，則其值預設為0；
-- 如果指定的整數值大於“9999-12-31 23:00:00”對應的整數值時，則其值預設設置為“9999-12-31 23:00:00”對應的整數值。
-- 結果值為基於預設基準日期開始計數的日期。
-- 作者: XXX
-- 創建: yyyy-MM-dd
-- 修改: yyyy-MM-dd XXX 修改內容描述
-- 調用: SET @dtmDate = dbo.fn_Hours2Date(947033) -- '2008-01-14 17:00'
--==================================
CREATE FUNCTION dbo.ufn_Hours2Date
(
@intHours INT -- 指定的整數值
) RETURNS DATETIME
AS
BEGIN
SET @intHours = dbo.ufn_GetValidDateNum(@intHours);
DECLARE @intMaxHours AS INT;
SET @intMaxHours = dbo.ufn_Hours(dbo.ufn_GetMaxDateTime());
IF @intHours >= @intMaxHours
BEGIN
SET @intHours = @intMaxHours;
END
RETURN DATEADD(HOUR, @intHours, dbo.ufn_GetDefaultBasedate());
END
GO
IF OBJECT_ID(N'dbo.ufn_HoursOfDay', 'FN') IS NOT NULL
BEGIN
DROP FUNCTION dbo.ufn_HoursOfDay;
END
GO
--==================================
-- 功能: 獲取指定的日期日期基於所在當期日午夜零時的小時數
-- 說明: 運行在SQL Server 2005+。
-- 結果值從0開始計數，包括0、1、2、……、23。
-- 作者: XXX
-- 創建: yyyy-MM-dd
-- 修改: yyyy-MM-dd XXX 修改內容描述
-- 調用: SET @tintHoursOfDay = dbo.ufn_HoursOfDay(GETDATE());
--==================================
CREATE FUNCTION dbo.ufn_HoursOfDay
(
@dtmDate DATETIME -- 指定的日期時間
)
RETURNS TINYINT
AS
BEGIN
RETURN DATEPART(HOUR, @dtmDate);
END
GO
-- Test Code
DECLARE @dtmDate AS DATETIME;
SET @dtmDate = '2014-02-14 6:12:00'
SELECT
@dtmDate AS 'The Current DateTime'
,dbo.ufn_Hours(@dtmDate) AS 'Hours'
,dbo.ufn_Hours2Date(dbo.ufn_Hours(@dtmDate)) AS 'DateTime Mapping Hours'
,dbo.ufn_HoursOfDay(@dtmDate) AS 'Hours Of The Current Day';
SET @dtmDate = '2014-05-20 8:18:00'
SELECT
@dtmDate AS 'The Current DateTime'
,dbo.ufn_Hours(@dtmDate) AS 'Hours'
,dbo.ufn_Hours2Date(dbo.ufn_Hours(@dtmDate)) AS 'DateTime Mapping Hours'
,dbo.ufn_HoursOfDay(@dtmDate) AS 'Hours Of The Current Day'
GO
以上3個函數的測試效果，如下圖：
周以上時間粒度基準日期有關函數，T-SQL代碼如下：
IF OBJECT_ID(N'dbo.ufn_FirstDayOfPeriodTable', 'IF') IS NOT NULL
BEGIN
DROP FUNCTION ufn_FirstDayOfPeriodTable;
END
GO
--==================================
-- 功能: 旬首日索引表
-- 說明: 運行在SQL Server 2005+。
-- 結果值為表數據，列名為FirstDayOfPeriod，其欄位列（域）值包括1、11、21這3個數字，其欄位列值對應每年每個旬的第一天。
-- 作者: XXX
-- 創建: yyyy-MM-dd
-- 修改: yyyy-MM-dd XXX 修改內容描述
-- 調用: SELECT * FROM dbo.ufn_FirstDayOfPeriodTable();
--==================================
CREATE FUNCTION dbo.ufn_FirstDayOfPeriodTable
(
) RETURNS TABLE
--$Encode$--
RETURN (
SELECT 1 AS FirstDayOfPeriod
UNION ALL SELECT 11
UNION ALL SELECT 21
);
GO
IF OBJECT_ID(N'dbo.ufn_FirstDayOfPeriod', N'FN') IS NOT NULL
BEGIN
DROP FUNCTION dbo.ufn_FirstDayOfPeriod;
END
GO
--==================================
-- 功能: 獲取指定的日期時間所在當前旬的第一個日索引
-- 說明: 運行在SQL Server 2005+。
-- 結果值從1開始計數，包括1、11、21。
-- 作者: XXX
-- 創建: yyyy-MM-dd
-- 修改: yyyy-MM-dd XXX 修改內容描述
-- 調用: SELECT @tintFirstDayOfPeriod = ufn_FirstDayOfPeriod(@dtmDate);
--==================================
CREATE FUNCTION dbo.ufn_FirstDayOfPeriod
(
@dtmDate DATETIME -- 指定的日期時間
) RETURNS TINYINT
--$Encode$--
BEGIN
DECLARE @tintFirstDayOfPeriod AS TINYINT;
SET @tintFirstDayOfPeriod = 1;
SELECT TOP 1 @tintFirstDayOfPeriod = FirstDayOfPeriod
FROM dbo.ufn_FirstDayOfPeriodTable()
WHERE FirstDayOfPeriod <= DAY(@dtmDate)
ORDER BY FirstDayOfPeriod DESC;
RETURN @tintFirstDayOfPeriod;
END
GO
IF OBJECT_ID(N'dbo.ufn_BasedateOfPeriod', 'FN') IS NOT NULL
BEGIN
DROP FUNCTION dbo.ufn_BasedateOfPeriod;
END
GO
--==================================
-- 功能: 獲取指定的日期時間所在旬的基準日期
-- 說明: 運行在SQL Server 2005+。
-- 結果值為旬基準日，即每個旬第一天對應的日期。
-- 作者: XXX
-- 創建: yyyy-MM-dd
-- 修改: yyyy-MM-dd XXX 修改內容描述
-- 調用: SET @dtmBasedateOfPeriod = dbo.ufn_BasedateOfPeriod('2016-01-12');
--==================================
CREATE FUNCTION dbo.ufn_BasedateOfPeriod
(
@dtmDate DATETIME -- 指定的日期時間
) RETURNS DATETIME
--$Encode$--
BEGIN
RETURN CONVERT(DATETIME, CAST(YEAR(@dtmDate) AS CHAR(4)) + '-' + CAST(MONTH(@dtmDate) AS VARCHAR(2)) + '-' + CAST(dbo.ufn_FirstDayOfPeriod(@dtmDate) AS VARCHAR(2)), 120);
END
GO
IF OBJECT_ID(N'dbo.ufn_BasedateOfMonth', 'FN') IS NOT NULL
BEGIN
DROP FUNCTION dbo.ufn_BasedateOfMonth;
END
GO
--==================================
-- 功能: 獲取指定日期時間所在月的基準日期
-- 說明: 運行在SQL Server 2005+。
-- 結果值為月基準日，即每個月第一天對應的日期。
-- 作者: XXX
-- 創建: yyyy-MM-dd
-- 修改: yyyy-MM-dd XXX 修改內容描述
-- 調用: SET @dtmBasedateOfMonth = dbo.ufn_BasedateOfMonth('2016-01-12');
--==================================
CREATE FUNCTION dbo.ufn_BasedateOfMonth
(
@dtmDate DATETIME -- 指定的日期時間
) RETURNS DATETIME
--$Encode$--
BEGIN
RETURN CONVERT(DATETIME, CAST(YEAR(@dtmDate) AS CHAR(4)) + '-' + CAST(MONTH(@dtmDate) AS VARCHAR(2)) + '-' + CAST(1 AS CHAR(1)), 120);
END
GO
IF OBJECT_ID(N'dbo.ufn_FirstMonthOfQuarterTable', 'IF') IS NOT NULL
BEGIN
DROP FUNCTION dbo.ufn_FirstMonthOfQuarterTable;
END
GO
--==================================
-- 功能: 季首月索引表
-- 說明: 運行在SQL Server 2005+。
-- 結果值為表數據，列名為FirstMonthOfQuarter，其欄位列（域）值包括1、4、7、10這4個數字，其欄位列值對應每年每個季的第一個月份。
-- 作者: XXX
-- 創建: yyyy-MM-dd
-- 修改: yyyy-MM-dd XXX 修改內容描述
-- 調用: SELECT * FROM dbo.ufn_FirstMonthOfQuarterTable();
--==================================
CREATE FUNCTION dbo.ufn_FirstMonthOfQuarterTable
(
) RETURNS TABLE
--$Encode$--
RETURN (
SELECT 1 AS FirstMonthOfQuarter
UNION ALL SELECT 4
UNION ALL SELECT 7
UNION ALL SELECT 10
);
GO
IF OBJECT_ID(N'dbo.ufn_FirstMonthOfQuarter', 'FN') IS NOT NULL
BEGIN
DROP FUNCTION dbo.ufn_FirstMonthOfQuarter;
END
GO
--==================================
-- 功能: 獲取指定的日期時間所在當前季度的第一個月索引
-- 說明: 運行在SQL Server 2005+。
-- 結果值從1開始計數，包括1、4、7、10。
-- 作者: XXX
-- 創建: yyyy-MM-dd
-- 修改: yyyy-MM-dd XXX 修改內容描述
-- 調用: SELECT @tintFirstMonthOfQuarter = ufn_FirstMonthOfQuarter(@dtmDate);
--==================================
CREATE FUNCTION dbo.ufn_FirstMonthOfQuarter
(
@dtmDate DATETIME -- 指定的日期時間
) RETURNS TINYINT
--$Encode$--
BEGIN
DECLARE @tintFirstMonthOfQuarter AS TINYINT;
SET @tintFirstMonthOfQuarter = 1;
SELECT TOP 1 @tintFirstMonthOfQuarter = FirstMonthOfQuarter
FROM dbo.ufn_FirstMonthOfQuarterTable()
WHERE FirstMonthOfQuarter <= MONTH(@dtmDate)
ORDER BY FirstMonthOfQuarter DESC;
RETURN @tintFirstMonthOfQuarter;
END
GO
IF OBJECT_ID(N'dbo.ufn_BasedateOfQuarter', 'FN') IS NOT NULL
BEGIN
DROP FUNCTION dbo.ufn_BasedateOfQuarter;
END
GO
--==================================
-- 功能: 獲取指定的日期時間所在當前季的季基準日期
-- 說明: 運行在SQL Server 2005+。
-- 結果值格式"XXXX-01-01"，包括："XXXX-01-01"、"XXXX-04-01"、"XXXX-07-01"、"XXXX-10-01"。
-- 作者: XXX
-- 創建: yyyy-MM-dd
-- 修改: yyyy-MM-dd XXX 修改內容描述
-- 調用: SELECT @tintFirstMonthOfQuarter = ufn_BasedateOfQuarter(@dtmDate);
--==================================
CREATE FUNCTION dbo.ufn_BasedateOfQuarter
(
@dtmDate DATETIME -- 指定的日期時間
) RETURNS DATETIME
--$Encode$--
BEGIN
RETURN CONVERT(DATETIME, CAST(YEAR(@dtmDate) AS CHAR(4)) + '-' + CAST(dbo.ufn_FirstMonthOfQuarter(@dtmDate) AS VARCHAR(2)) + '-' + CAST(1 AS CHAR(1)), 120);
END
GO
IF OBJECT_ID(N'dbo.ufn_BasedateOfYear', 'FN') IS NOT NULL
BEGIN
DROP FUNCTION dbo.ufn_BasedateOfYear;
END
GO
--==================================
-- 功能: 獲取指定日期時間所在年的基準日期
-- 說明: 結果值是每個年的基準日，每個年第一天對應的日期。
-- 作者: XXX
-- 創建: yyyy-MM-dd
-- 修改: yyyy-MM-dd XXX 修改內容描述
-- 調用: SET @dtmBasedateOfYear = dbo.ufn_BasedateOfYear('2016-01-12');
--==================================
CREATE FUNCTION dbo.ufn_BasedateOfYear
(
@dtmDate DATETIME -- 指定的日期時間
) RETURNS DATETIME
--$Encode$--
BEGIN
RETURN CONVERT(DATETIME, CAST(YEAR(@dtmDate) AS CHAR(4)) + '-' + CAST(1 AS CHAR(1)) + '-' + CAST(1 AS char(1)), 120);
END
GO
-- Test Code
DECLARE @dtmDate AS DATETIME;
SET @dtmDate = '2016-01-14';
SELECT
@dtmDate AS 'The Current Date'
,dbo.ufn_BasedateOfPeriod(@dtmDate) AS 'Basedate Of The Current Period'
,dbo.ufn_BasedateOfMonth(@dtmDate) AS 'Basedate Of The Current Month'
,dbo.ufn_BasedateOfQuarter(@dtmDate) AS 'Basedate Of the Current Quarter'
,dbo.ufn_BasedateOfYear(@dtmDate) AS 'Basedate Of the Current Year'
,dbo.ufn_GetMinDateTime() AS 'Basedate Of the Current Date';
SET @dtmDate = '2016-4-30';
SELECT
@dtmDate AS 'The Current Date'
,dbo.ufn_BasedateOfPeriod(@dtmDate) AS 'Basedate Of The Current Period'
,dbo.ufn_BasedateOfMonth(@dtmDate) AS 'Basedate Of The Current Month'
,dbo.ufn_BasedateOfQuarter(@dtmDate) AS 'Basedate Of the Current Quarter'
,dbo.ufn_BasedateOfYear(@dtmDate) AS 'Basedate Of the Current Year'
,dbo.ufn_GetMinDateTime() AS 'Basedate Of the Current Date';
GO
以上幾個函數的測試效果，如下圖：
天時間粒度有關函數，T-SQL代碼如下：
IF OBJECT_ID(N'dbo.ufn_Days', 'FN') IS NOT NULL
BEGIN
DROP FUNCTION dbo.ufn_Days;
END
GO
--==================================
-- 功能: 獲得指定日期時間基於預設基準日期的總天數(一個整數值）
-- 說明: 運行在SQL Server 2005+。
-- 如果指定的日期時間為NULL或者小於預設基準日期時，則其值為預設基準日期。
-- 結果值為非負整數，從0開始計數。
-- 作者: XXX
-- 創建: yyyy-MM-dd
-- 修改: yyyy-MM-dd XXX 修改內容描述
-- 調用: SET @intDays = dbo.ufn_Days('2008-01-14')
--==================================
CREATE FUNCTION dbo.ufn_Days
(
@dtmDate DATETIME -- 指定的日期時間
) RETURNS INT
--$Encode$--
AS
BEGIN
RETURN DATEDIFF(DAY, dbo.ufn_GetDefaultBasedate(), dbo.ufn_GetValidDate(@dtmDate));
END
GO
IF OBJECT_ID(N'dbo.ufn_Days2Date', 'FN') IS NOT NULL
BEGIN
DROP FUNCTION dbo.ufn_Days2Date;
END
GO
--==================================
-- 功能: 獲得一個整數值基於預設基準日期對應的日期
-- 說明: 運行在SQL Server 2005+。
-- 如果指定的整數值為NULL或為負整數時，則其值預設為0。
-- 如果指定的整數值大於最大日期時間對應的整數值時，則其值預設設置為最大日期時間對應的整數值。
-- 結果值為基於預設基準日期開始計數的日期。
-- 作者: XXX
-- 創建: yyyy-MM-dd
-- 修改: yyyy-MM-dd XXX 修改內容描述
-- 調用: SET @dtmDate = dbo.ufn_Days2Date(39459) --'2008-01-14'
--==================================
CREATE FUNCTION dbo.ufn_Days2Date
(
@intDays INT -- 指定的整數值
) RETURNS DATETIME
--$Encode$--
AS
BEGIN
SET @intDays = dbo.ufn_GetValidDateNum(@intDays);
DECLARE @intMaxDays AS INT;
SET @intMaxDays = dbo.ufn_Days(dbo.ufn_GetMaxDateTime());
IF @intDays >= @intMaxDays
BEGIN
SET @intDays = @intMaxDays;
END
RETURN DATEADD(DAY, @intDays, dbo.ufn_GetDefaultBasedate());
END
GO
IF OBJECT_ID(N'dbo.ufn_DayOfWeek', 'FN') IS NOT NULL
BEGIN
DROP FUNCTION dbo.ufn_DayOfWeek;
END
GO
--==================================
-- 功能: 獲取指定日期時間的所在當前周的日索引
-- 說明: 運行在SQL Server 2005+。
-- 結果值從1到7，分別對應從周一到周日，該值與@@DATEFISRT配置函數值保持一致。
-- 使用(@@datefirt + datepart(weekday, @dtmDate))%7的結果值從2、3、4、5、6、0、1
-- 分別對應周一、周二、周三、周四、周五、周六、周日。
-- 作者: XXX
-- 創建: yyyy-MM-dd
-- 修改: yyyy-MM-dd XXX 修改內容描述
-- 調用: SELECT dbo.ufn_DayOfWeek('2017-01-07') -- 4（表示星期四）
--==================================
CREATE FUNCTION dbo.ufn_DayOfWeek
(
@dtmDate DATETIME -- 指定的日期時間
) RETURNS TINYINT
--$Encode$--
BEGIN
DECLARE @tintRemainder AS TINYINT;
SET @tintRemainder = (@@DATEFIRST + DATEPART(WEEKDAY, @dtmDate)) % 7;
IF @tintRemainder <= 1
BEGIN
SET @tintRemainder = @tintRemainder + 6;
END
ELSE
BEGIN
SET @tintRemainder = @tintRemainder - 1;
END
RETURN @tintRemainder;
END
GO
IF OBJECT_ID(N'dbo.ufn_DayOfPeriod', 'FN') IS NOT NULL
BEGIN
DROP FUNCTION dbo.ufn_DayOfPeriod;
END
GO
--==================================
-- 功能: 獲得指定日期時間在當前旬的日索引
-- 說明: 運行在SQL Server 2005+。
-- 結果值從1開始計數，包括1、2、3、……、8、9、10、11。
-- 作者: XXX
-- 創建: yyyy-MM-dd
-- 修改: yyyy-MM-dd XXX 修改內容描述
-- 調用: SET @intPeriods = dbo.ufn_DayOfPeriod('2008-01-14')
--==================================
CREATE FUNCTION dbo.ufn_DayOfPeriod
(
@dtmDate DATETIME -- 指定的日期時間
) RETURNS TINYINT
--$Encode$--
AS
BEGIN
--RETURN DAY(@dtmDate) - (dbo.ufn_PeriodOfMonth(@dtmDate) - 1) * 10;
RETURN DATEDIFF(DAY, dbo.ufn_BasedateOfPeriod(@dtmDate), @dtmDate) + 1;
END
GO
IF OBJECT_ID(N'dbo.ufn_DayOfMonth', 'FN') IS NOT NULL
BEGIN
DROP FUNCTION dbo.ufn_DayOfMonth;
END
GO
--==================================
-- 功能: 獲取指定的日期時間所在當前月的日索引
-- 說明: 運行在SQL Server 2005+。
-- 結果值從1開始計數，包括1、2、3.……、28、29、30、31。
-- 作者: XXX
-- 創建: yyyy-MM-dd
-- 修改: yyyy-MM-dd XXX 修改內容描述
-- 調用: SET @sintDayOfYear = dbo.ufn_DayOfMonth('2016-01-11')
--==================================
CREATE FUNCTION dbo.ufn_DayOfMonth
(
@dtmDate DATETIME -- 指定的日期時間
) RETURNS TINYINT
--$Encode$--
BEGIN
RETURN DAY(@dtmDate);
END
GO
IF OBJECT_ID(N'dbo.ufn_DayOfQuarter', 'FN') IS NOT NULL
BEGIN
DROP FUNCTION dbo.ufn_DayOfQuarter;
END
GO
--==================================
-- 功能: 獲取指定的日期時間所在季的日索引
-- 說明: 運行在SQL Server 2005+。
-- 結果值從1開始計數，包括1、2、3.……、89、90、91、92。
-- 作者: XXX
-- 創建: yyyy-MM-dd
-- 修改: yyyy-MM-dd XXX 修改內容描述
--==================================
CREATE FUNCTION dbo.ufn_DayOfQuarter
(
@dtmDate DATETIME -- 指定的日期時間
) RETURNS TINYINT
--$Encode$--
BEGIN
RETURN DATEDIFF(DAY, dbo.ufn_BasedateOfQuarter(@dtmDate), @dtmDate) + 1;
END
GO
IF OBJECT_ID(N'dbo.ufn_DayOfYear', 'FN') IS NOT NULL
BEGIN
DROP FUNCTION dbo.ufn_DayOfYear;
END
GO
--==================================
-- 功能: 獲取指定的日期時間所在當前年的日索引
-- 說明: 運行在SQL Server 2005+。
-- 結果值從1開始計數，包括1、2、3.……、364、365、366。
-- 作者: XXX
-- 創建: yyyy-MM-dd
-- 修改: yyyy-MM-dd XXX 修改內容描述
-- 調用: SET @sintDayOfYear = dbo.ufn_DayOfYear('2016-01-11')
--==================================
CREATE FUNCTION dbo.ufn_DayOfYear
(
@dtmDate DATETIME -- 指定的日期時間
) RETURNS SMALLINT
--$Encode$--
BEGIN
RETURN DATEPART(DAYOFYEAR, @dtmDate);
END
GO
IF OBJECT_ID(N'dbo.ufn_DayOfDate', 'FN') IS NOT NULL
BEGIN
DROP FUNCTION dbo.ufn_DayOfDate;
END
GO
--==================================
-- 功能: 獲取指定的日期時間所在當前日期的日索引
-- 說明: 運行在SQL Server 2005+。
-- 結果值從1開始計數，包括1、2、3.……、3652057、3652058、3652059。
-- 作者: XXX
-- 創建: yyyy-MM-dd
-- 修改: yyyy-MM-dd XXX 修改內容描述
-- 調用: SET @inntDayOfDate = dbo.ufn_DayOfDate('2016-01-11')
--==================================
CREATE FUNCTION dbo.ufn_DayOfDate
(
@dtmDate DATETIME
) RETURNS INT
--$Encode$--
BEGIN
RETURN DATEDIFF(DAY, dbo.ufn_GetMinDateTime(), dbo.ufn_GetValidDate(@dtmDate)) + 1
END
GO
-- Test Code
DECLARE @dtmDate AS DATETIME;
SET @dtmDate = '2016-01-14';
SELECT
@dtmDate AS 'The Current Date'
,dbo.ufn_Days(@dtmDate) AS 'Days'
,dbo.ufn_Days2Date(dbo.ufn_Days(@dtmDate)) AS 'Date Mapping Days'
,dbo.ufn_DayOfWeek(@dtmDate) AS 'Day Of The Current Week'
,dbo.ufn_DayOfPeriod(@dtmDate) AS 'Day Of The Current Period'
,dbo.ufn_DayOfMonth(@dtmDate) AS 'Day Of The Current Month'
,dbo.ufn_DayOfQuarter(@dtmDate) AS 'Day Of The Current Quarter'
,dbo.ufn_DayOfYear(@dtmDate) AS 'Day Of The Current Year'
,dbo.ufn_DayOfDate(@dtmDate) AS 'Day Of The Current Date';
SET @dtmDate = '2016-03-14';
SELECT
@dtmDate AS 'The Current Date'
,dbo.ufn_Days(@dtmDate) AS 'Days'
,dbo.ufn_Days2Date(dbo.ufn_Days(@dtmDate)) AS 'Date Mapping Days'
,dbo.ufn_DayOfWeek(@dtmDate) AS 'Day Of The Current Week'
,dbo.ufn_DayOfPeriod(@dtmDate) AS 'Day Of The Current Period'
,dbo.ufn_DayOfMonth(@dtmDate) AS 'Day Of The Current Month'
,dbo.ufn_DayOfQuarter(@dtmDate) AS 'Day Of The Current Quarter'
,dbo.ufn_DayOfYear(@dtmDate) AS 'Day Of The Current Year'
,dbo.ufn_DayOfDate(@dtmDate) AS 'Day Of The Current Date';
GO
以上幾個函數的測試效果，如下圖：
周時間粒度有關函數，T-SQL代碼如下：
IF OBJECT_ID(N'dbo.ufn_Weeks', 'FN') IS NOT NULL
BEGIN
&nb
