調用 start_kernel

来源:https://www.cnblogs.com/jiau/archive/2020/05/25/12958093.html
-Advertisement-
Play Games

步驟 1 關閉中斷、進入 SVC 模式 步驟 2 查找指定處理器類型的 proc_info 步驟 3 檢查 bootloader 傳遞的啟動參數是否有效 步驟 4 當前內核鏡像在記憶體中的佈局 內核建立內核空間臨時的線性映射，採用一級映射，也就是 section 模式，每個section 為 1MB. ...


步驟 1

關閉中斷、進入 SVC 模式

ENTRY(stext)
	 THUMB(	adr	r9, BSYM(1f)	)	@ Kernel is always entered in ARM.
	 THUMB(	bx	r9		)	@ If this is a Thumb-2 kernel,
	 THUMB(	.thumb			)	@ switch to Thumb now.
	 THUMB(1:			)
		setmode	PSR_F_BIT | PSR_I_BIT | SVC_MODE, r9 @ 關中斷、進入 SVC 模式

步驟 2

查找指定處理器類型的 proc_info

	mrc	p15, 0, r9, c0, c0		@ 取出處理器 ID 放入寄存器 r9 中
	bl	__lookup_processor_type		@ 查找處理器類型 r5=procinfo r9=cpuid
	|
	|-->/* 找到匹配 proc_info 則返回，否則將 r5 清零 */
	|		__CPUINIT
	|	__lookup_processor_type:
	|		adr	r3, __lookup_processor_type_data
	|			|
	|			|-->.align	2
	|			|		.type	__lookup_processor_type_data, %object
	|			|	__lookup_processor_type_data:
	|			|		.long	.
	|			|		.long	__proc_info_begin
	|			|		.long	__proc_info_end
	|			|		.size	__lookup_processor_type_data, . - __lookup_processor_type_data
	|		ldmia	r3, {r4 - r6}	@ r4=當前數據地址、r5=處理器數據起始地址、r6=結束地址
	|		sub	r3, r3, r4			@ 計算出運行地址和鏈接地址間的偏移
	|		add	r5, r5, r3			@ 修正 r5
	|		add	r6, r6, r3			@ 修正 r6
	|	1:	ldmia	r5, {r3, r4}
	|		and	r4, r4, r9
	|		teq	r3, r4
	|		beq	2f					@ 如果相等則匹配成功
	|		add	r5, r5, #PROC_INFO_SZ	@ 開始指向下一個處理器數據
	|		cmp	r5, r6
	|		blo	1b					@ 如果還有數據則迴圈查找
	|		mov	r5, #0				@ 未找到時將 r5 清零
	|	2:	mov	pc, lr				@ 返回
	|	ENDPROC(__lookup_processor_type)
	
	movs	r10, r5			@ 使用 r5 改變標誌位
	THUMB( it	eq )
	beq	__error_p			@ 如果相等則沒找到
	
#ifndef CONFIG_XIP_KERNEL
	adr	r3, 2f				@ r3=運行地址
	ldmia	r3, {r4, r8}	@ r4=鏈接地址(虛擬地址)、r8=頁偏移
	sub	r4, r3, r4			@ 運行地址與鏈接地址間的差值
	/*
	 * 內核被解壓到 物理地址+text_offset 處，即 0x40008000，也是當前的運行地址
	 * 而內核在編譯時被鏈接到 page_offset+text_offset 處，即 0xc0008000
	 * 因此 r4=r3-r4 記錄的是內核實際存放的物理地址和運行時的虛擬地址間的偏移
	 * 即 r4=phys-page_offset
	 * 所以 r8 = r4+r8 = phys-page_offset+page_offset = phys，即物理地址的起始地址
	 */
	add	r8, r8, r4			@ 物理地址的起始地址
#else
	ldr	r8, =PHYS_OFFSET	@ always constant in this case
#endif

#ifndef CONFIG_XIP_KERNEL
2:	.long	.
	.long	PAGE_OFFSET
#endif

步驟 3

檢查 bootloader 傳遞的啟動參數是否有效

/*
 * r1 = machine no, r2 = atags or dtb,
 * r8 = phys_offset, r9 = cpuid, r10 = procinfo
 */
bl	__vet_atags
	|
	+-->/* Returns:
	|	 *  r2 either valid atags pointer, valid dtb pointer, or zero
	|	 *  r5, r6 corrupted
	|	 */
	|	__vet_atags:
	|		tst	r2, #0x3			@ 判斷 atags 是否 4 位元組對齊
	|		bne	1f
	|
	|		ldr	r5, [r2, #0]
	|	#ifdef CONFIG_OF_FLATTREE	@ 配置此項時支持設備樹
	|		ldr	r6, =OF_DT_MAGIC	@ 判斷是否是 DTB 數據
	|		cmp	r5, r6
	|		beq	2f
	|	#endif
	|		cmp	r5, #ATAG_CORE_SIZE		@ 判斷第一個 atags 參數的大小是否是與 ATAG_CORE 相同
	|		cmpne	r5, #ATAG_CORE_SIZE_EMPTY
	|		bne	1f
	|		ldr	r5, [r2, #4]
	|		ldr	r6, =ATAG_CORE			@ 再判斷該參數是不是 ATAG_CORE 節點
	|		cmp	r5, r6
	|		bne	1f
	|
	|	2:	mov	pc, lr				@ 所傳遞參數合法，正常返回
	|
	|	1:	mov	r2, #0
	|		mov	pc, lr
	|	ENDPROC(__vet_atags)

步驟 4

當前內核鏡像在記憶體中的佈局

// 物理記憶體中的佈局
       _____________________________________________
      |      |          |                          |
      |      |          |                          |
      |      | 段描述符 |       kernel image       |
      |      |          |                          |
      |______|__________|__________________________|
0x4000_0000      0x4000_8000

// 虛擬記憶體中的佈局
       _____________________________________________
      |      |          |                          |
      |      |          |                          |
      |      | 段描述符 |       kernel image       |
      |      |          |                          |
      |______|__________|__________________________|
0xc000_0000      0xc000_8000

內核建立內核空間臨時的線性映射，採用一級映射，也就是 section 模式，每個section 為 1MB.

#ifdef CONFIG_SMP_ON_UP
	bl	__fixup_smp			@ 自旋鎖在 SMP 和 UP 上的相關修正
							@ arch/arm/include/asm::ALT_SMP
#endif
#ifdef CONFIG_ARM_PATCH_PHYS_VIRT
	bl	__fixup_pv_table	@ 物理地址和虛擬地址間的偏移修正等
							@ arch/arm/include/asm::pv_stub
#endif
	bl	__create_page_tables
	|	
	+-->/* r8 = phys_offset, r9 = cpuid, r10 = procinfo
	|	 *
	|	 * Returns:
	|	 *  r0, r3, r5-r7 corrupted
	|	 *  r4 = physical page table address
	|	 */
	|	__create_page_tables:
	|		pgtbl	r4, r8				@ 將頁表起始物理地址放入 r4 中
	|			|
	|			+-->.macro	pgtbl, rd, phys
	|			|	add	\rd, \phys, #TEXT_OFFSET - PG_DIR_SIZE
	|			|	.endm
	|
	|		@ 對頁表區域進行清零
	|		mov	r0, r4
	|		mov	r3, #0
	|		add	r6, r0, #PG_DIR_SIZE
	|	1:	str	r3, [r0], #4
	|		str	r3, [r0], #4
	|		str	r3, [r0], #4
	|		str	r3, [r0], #4
	|		teq	r0, r6
	|		bne	1b
	|
	|		ldr	r7, [r10, #PROCINFO_MM_MMUFLAGS] @ mm_mmuflags
	|
	|		@ 創建臨時的線性映射
	|		@ 頁表項格式：一級頁表入口值[31:20]  MMUFLAGS[19:0]
	|		adr	r0, __turn_mmu_on_loc
	|		ldmia	r0, {r3, r5, r6}@ 得到函數的物理地址
	|		sub	r0, r0, r3			@ virt->phys offset
	|		add	r5, r5, r0			@ phys __turn_mmu_on
	|		add	r6, r6, r0			@ phys __turn_mmu_on_end
	|		mov	r5, r5, lsr #SECTION_SHIFT @ 得到一級頁表入口值
	|		mov	r6, r6, lsr #SECTION_SHIFT
	|
	|	1:	orr	r3, r7, r5, lsl #SECTION_SHIFT	@ 一級段描述符
	|		str	r3, [r4, r5, lsl #PMD_ORDER]	@ 將 r3 中存放的段描述符放入對應的物理地址中
	|		cmp	r5, r6
	|		addlo	r5, r5, #1			@ 下一個段描述符
	|		blo	1b
	|
	|		@ 設置映射頁表
	|		mov	r3, pc
	|		mov	r3, r3, lsr #SECTION_SHIFT @ 得到當前執行程式的段描述符編號
	|		orr	r3, r7, r3, lsl #SECTION_SHIFT @ 合成段描述符
	|		@ kernel_start=0xc000_8000, section_shift=20, pmd_order=2
	|		@ 以下兩行其實是在計算段描述符的入口地址
	|		@ 因為要回寫到 r0 中，因此拆分來寫的
	|		add	r0, r4,  #(KERNEL_START & 0xff000000) >> (SECTION_SHIFT - PMD_ORDER)
	|		str	r3, [r0, #((KERNEL_START & 0x00f00000) >> SECTION_SHIFT) << PMD_ORDER]!
	|		ldr	r6, =(KERNEL_END - 1) @ 內核(包括數據段)的最後一個位元組位置
	|		add	r0, r0, #1 << PMD_ORDER @ 下一個段描述符存放的物理地址
	|		add	r6, r4, r6, lsr #(SECTION_SHIFT - PMD_ORDER) @ 內核需要的最後一個段描述符存放的物理地址
	|	1:	cmp	r0, r6
	|		@ 內核對自身進行了線性映射，將自身物理記憶體所在段直接放入頁表中
	|		add	r3, r3, #1 << SECTION_SHIFT @ 下一個段描述符，只需要增加段基址即可
	|		strls	r3, [r0], #1 << PMD_ORDER @ 寫入到物理記憶體對應的頁表中
	|		bls	1b
	|
	|		@ 將 atags 所在段寫到頁表中
	|		mov	r0, r2, lsr #SECTION_SHIFT @ atags 段編號
	|		movs	r0, r0, lsl #SECTION_SHIFT @ 如果 r0 為零則賦值為 r8，即沒有指定 atags 的情況
	|		moveq	r0, r8
	|		sub	r3, r0, r8 @ 段內偏移量
	|		add	r3, r3, #PAGE_OFFSET @ 轉化成虛擬地址
	|		add	r3, r4, r3, lsr #(SECTION_SHIFT - PMD_ORDER) @ 得到該段描述符存放的物理地址
	|		orr	r6, r7, r0 @ 合成段描述
	|		str	r6, [r3]   @ 寫入物理記憶體中
	|
	|		mov	pc, lr
	|		ENDPROC(__create_page_tables)
	
	/*
	 * r10 = base of xxx_proc_info structure selected by __lookup_processor_type
	 * On return, the CPU will be ready for the MMU to be turned on, 
	 * r0 = CPU control register value.
	 */
	 /*
	  * 以下代碼流程 
	  * 1. 設置v7核心，主要涉及SMP，準備MMU硬體配置，I/D cache，TLB，涉及協處理的配置
	  * --> arch/arm/mm/proc-v7.S::__v7_setup
	  * 2. 配置MMU，設置記憶體訪問許可權，並激活MMU
	  * --> arch/arm/kernel/head.S::__enable_mmu
	  * 3. 將數據段複製到記憶體中，清理bss段，將processor ID，machine ID，atags 指針保存到指定變數中
	  * --> arch/arm/kernel/head-common.S::__mmap_switched
	  * 4. __mmap_switched 最後進入C語言函數start_kernel，至此終於走出了彙編代碼，進入C語言的天堂
	  * --> init/main.c::start_kernel
	  */
	@ 因為跳轉到該函數時，MMU已激活，故這裡使用的是虛擬地址，而不是物理地址
	ldr	r13, =__mmap_switched	@ address to jump to after
								@ mmu has been enabled
	adr	lr, BSYM(1f)			@ return (PIC) address
	mov	r8, r4					@ set TTBR1 to swapper_pg_dir
	ARM(	add	pc, r10, #PROCINFO_INITFUNC	)
	THUMB(	add	r12, r10, #PROCINFO_INITFUNC	)
	THUMB(	mov	pc, r12				)
1:	b	__enable_mmu

關鍵巨集定義

::arch/arm/kernel/vmlinux.ld.S
. = PAGE_OFFSET + TEXT_OFFSET
::arcm/arm/kernel/head.S
/*
 * swapper_pg_dir is the virtual address of the initial page table.
 * We place the page tables 16K below KERNEL_RAM_VADDR.  Therefore, we must
 * make sure that KERNEL_RAM_VADDR is correctly set.  Currently, we expect
 * the least significant 16 bits to be 0x8000, but we could probably
 * relax this restriction to KERNEL_RAM_VADDR >= PAGE_OFFSET + 0x4000.
 */
#define KERNEL_RAM_VADDR	(PAGE_OFFSET + TEXT_OFFSET)
#if (KERNEL_RAM_VADDR & 0xffff) != 0x8000
#error KERNEL_RAM_VADDR must start at 0xXXXX8000
#endif

#ifdef CONFIG_ARM_LPAE
	/* LPAE requires an additional page for the PGD */
#define PG_DIR_SIZE	0x5000
#define PMD_ORDER	3
#else
#define PG_DIR_SIZE	0x4000
#define PMD_ORDER	2
#endif

	.globl	swapper_pg_dir
	.equ	swapper_pg_dir, KERNEL_RAM_VADDR - PG_DIR_SIZE

	.macro	pgtbl, rd, phys
	add	\rd, \phys, #TEXT_OFFSET - PG_DIR_SIZE
	.endm

#ifdef CONFIG_XIP_KERNEL
#define KERNEL_START	XIP_VIRT_ADDR(CONFIG_XIP_PHYS_ADDR)
#define KERNEL_END	_edata_loc
#else
#define KERNEL_START	KERNEL_RAM_VADDR
#define KERNEL_END	_end
#endif

您的分享是我們最大的動力!

-Advertisement-
Play Games
更多相關文章
  • Linux命令（24）clear命令
    clear命令 功能說明：用於清屏，只保留一行命令提示符。也可以使用Ctrl+L快捷鍵。 用法：clear 示例：清除當前的屏幕。 ...
  • Linux命令（23）usermod命令
    usermod命令 功能說明：修改用戶屬性 用法：usermod [options] login_name | 選項 | 作用 | | | | | u， uid UID | 修改用戶的ID為此處指定的新UID | | g， gid group_name | 修改用戶所屬的基本組，不過此組得事先存在 ...
  • Linux命令（22）useradd命令
    useradd命令 功能說明：添加用戶或更新預設的新用戶信息 用法：useradd [options] login_name | 選項 | 說明 | | | | | u， uid UID | 添加一個新的用戶時，手動指定UID號，預設是上一個用戶的UID+1，UID使用範圍（CentOS6）500+ ...
  • 手把手教你Windows Linux雙系統的安裝與卸載
    作者：—葉丶知秋 鏈接：https://blog.csdn.net/fanxueya1322/article/details/90205143 轉載請保留出處 良許前言： 後臺突然有很多小伙伴留言想看 Linux+Windows 雙系統的安裝，本想自己寫一個，但看了一眼自己那台服役快6年的老古董，想 ...
  • 公有雲技術
    公有雲技術 公有云云伺服器的申請與使用 華為雲介紹 華為雲立足於互聯網領域，依托於華為公司雄厚的資本和強大的雲計算研發實力，面向互聯網增值服務運營商、大中小型企業、政府、科研院所等廣大企事業用戶提供包括雲主機、雲托管、雲存儲等基礎雲服務、超算、內容分發與加速、視頻托管與發佈、企業IT、雲電腦、雲會議 ...
  • ahjesus-全網僅此一份 kali linux 中文教程 learn kali 漢化版
    kali linux 中文教程 learn kali 漢化版閑言碎語不要講，曬圖有真相 下載百度網盤 提取碼: 1ie4 ...
  • HeartBeat基礎配置（實現Web服務雙機熱備）
    Heartbeat 項目是 Linux-HA 工程的一個組成部分，它實現了一個高可用集群系統。心跳服務和集群通信是高可用集群的兩個關鍵組件，在 Heartbeat 項目里，由 heartbeat 模塊實現了這兩個功能。本實驗實現web伺服器的主備雙熱備份系統Linux系統：Linux6.8規劃:2台... ...
  • 容器技術之Docker數據捲
    捲為docker提供了獨立於容器的數據管理機制；我們可以把鏡像想象成靜態文件，例如程式，把捲類比成動態內容，比如數據，於是鏡像可以復用，而捲可以共用；捲實現了程式（鏡像）和數據（捲）的分離；實現了容器之間的數據共用和復用，使得容器間傳遞數據變得高效方便；對數據捲內數據的修改會立馬生效，無論是在容器... ...
一周排行
    -Advertisement-
    Play Games
  • Dapr Outbox 執行流程
    Dapr Outbox 是1.12中的功能。 本文只介紹Dapr Outbox 執行流程，Dapr Outbox基本用法請閱讀官方文檔 。本文中appID=order-processor，topic=orders 本文前提知識：熟悉Dapr狀態管理、Dapr發佈訂閱和Outbox 模式。 Outbo ...
  • Advanced .Net Debugging 7：托管堆與垃圾收集
    引言 在前幾章我們深度講解了單元測試和集成測試的基礎知識，這一章我們來講解一下代碼覆蓋率,代碼覆蓋率是單元測試運行的度量值,覆蓋率通常以百分比表示，用於衡量代碼被測試覆蓋的程度，幫助開發人員評估測試用例的質量和代碼的健壯性。常見的覆蓋率包括語句覆蓋率（Line Coverage）、分支覆蓋率（Bra ...
  • C#S7.NET實現西門子PLCDB塊數據採集的完整步驟
    前言 本文介紹瞭如何使用S7.NET庫實現對西門子PLC DB塊數據的讀寫，記錄了使用電腦模擬，模擬PLC，自至完成測試的詳細流程，並重點介紹了在這個過程中的易錯點，供參考。 用到的軟體： 1.Windows環境下鏈路層網路訪問的行業標準工具（WinPcap_4_1_3.exe）下載鏈接：http ...
  • WPF控制項：密碼框綁定MVVM
    從依賴倒置原則（Dependency Inversion Principle, DIP）到控制反轉（Inversion of Control, IoC）再到依賴註入（Dependency Injection, DI）的演進過程，我們可以理解為一種逐步抽象和解耦的設計思想。這種思想在C#等面向對象的編 ...
  • Python中的私有屬性與私有方法
    關於Python中的私有屬性和私有方法 Python對於類的成員沒有嚴格的訪問控制限制，這與其他面相對對象語言有區別。關於私有屬性和私有方法，有如下要點： 1、通常我們約定，兩個下劃線開頭的屬性是私有的（private）。其他為公共的（public）； 2、類內部可以訪問私有屬性（方法）； 3、類外 ...
  • C++ 訪問說明符詳解：封裝數據，控制訪問，提升安全性
    C++ 訪問說明符 訪問說明符是 C++ 中控制類成員（屬性和方法）可訪問性的關鍵字。它們用於封裝類數據並保護其免受意外修改或濫用。 三種訪問說明符： public：允許從類外部的任何地方訪問成員。 private：僅允許在類內部訪問成員。 protected：允許在類內部及其派生類中訪問成員。 示 ...
  • static_cast與dynamic_cast到底是什麼？
    寫這個隨筆說一下C++的static_cast和dynamic_cast用在子類與父類的指針轉換時的一些事宜。首先，【static_cast，dynamic_cast】【父類指針，子類指針】，兩兩一組，共有4種組合：用 static_cast 父類轉子類、用 static_cast 子類轉父類、使用 ...
  • C語言數據結構：雙向鏈表的增刪操作
    /******************************************************************************************************** * * * 設計雙向鏈表的介面 * * * * Copyright (c) 2023-2 ...
  • @ComponentScan註解的實現，Spring掃描包的過程
    相信接觸過spring做開發的小伙伴們一定使用過@ComponentScan註解 @ComponentScan("com.wangm.lifecycle") public class AppConfig { } @ComponentScan指定basePackage，將包下的類按照一定規則註冊成Be ...
  • opensips開啟python支持
    操作系統 ：CentOS 7.6_x64 opensips版本： 2.4.9 python版本：2.7.5 python作為腳本語言，使用起來很方便，查了下opensips的文檔，支持使用python腳本寫邏輯代碼。今天整理下CentOS7環境下opensips2.4.9的python模塊筆記及使用 ...
所有分類