PowerDesigner通過SQL語句生成PDM文件並將name和comment進行互相轉換

本篇文章主要介紹了PowerDesigner通過SQL語句生成PDM文件並將name和comment進行互相轉換 超詳細過程（圖文），具有一定的參考價值，感興趣的小伙伴們可以參考一下

1.軟體準備

軟體：Navicat 11.1，Powerdesigner 15

2.安裝步驟

第一步：將要生成的資料庫導出為sql文件

第二步：打開PowerDesigner選擇File-->Reverse Engineer --> Database...

第三步：選擇MySQL5.0資料庫

第四步：找到第一步生成的Sql文件，點擊確定即可

PowerDesigner中NAME和COMMENT的互相轉換,需要執行語句

由於PDM 的表中 Name 會預設=Code 所以很不方便, 所以需要將 StereoType 顯示到表的外面來

打開[工具]->[顯示屬性](英文:Display Preferences) ->Content->Table->右邊面板Columns框中 勾選: StereoType ,這樣再在 StereoType中填入code欄位相同內容就會顯示在圖形界面上了

使用說明: 在【Tools】-【Execute Commands】-【Edit/Run Script】 下。輸入下麵你要選擇的語句即可，也可以保存起來，以便下次使用，尾碼為.vbs。

 需要註意的問題是：運行語句時必須在Module模式下，如果是導出報表時執行會出現錯誤提示。

1.Name轉到Comment註釋欄位。一般情況下只填寫NAME，COMMENT可以運行語句自動生成。

將該語句保存為name2comment.vbs

'把pd中那麼name想自動添加到comment裡面
'如果comment為空,則填入name;如果不為空,則保留不變,這樣可以避免已有的註釋丟失.

Option   Explicit 
ValidationMode   =   True 
InteractiveMode   =   im_Batch 

Dim   mdl   '   the   current   model 

'   get   the   current   active   model 
Set   mdl   =   ActiveModel 
If   (mdl   Is   Nothing)   Then 
      MsgBox   "There   is   no   current   Model " 
ElseIf   Not   mdl.IsKindOf(PdPDM.cls_Model)   Then 
      MsgBox   "The   current   model   is   not   an   Physical   Data   model. " 
Else 
      ProcessFolder   mdl 
End   If 

'   This   routine   copy   name   into   comment   for   each   table,   each   column   and   each   view 
'   of   the   current   folder 
Private   sub   ProcessFolder(folder)    
      Dim   Tab   'running     table    
      for   each   Tab   in   folder.tables    
            if   not   tab.isShortcut then
                     if  trim(tab.comment)="" then'如果有表的註釋,則不改變它.如果沒有表註釋.則把name添加到註釋裡面.
                        tab.comment   =   tab.name
                     end if  
                  Dim   col   '   running   column    
                  for   each   col   in   tab.columns   
                        if trim(col.comment)="" then '如果col的comment為空,則填入name,如果已有註釋,則不添加;這樣可以避免已有註釋丟失.
                           col.comment=   col.name   
                        end if 
                  next    
            end   if    
      next    
  
      Dim   view   'running   view    
      for   each   view   in   folder.Views    
            if   not   view.isShortcut and trim(view.comment)=""  then    
                  view.comment   =   view.name    
            end   if    
      next    
  
      '   go   into   the   sub-packages    
      Dim   f   '   running   folder    
      For   Each   f   In   folder.Packages    
            if   not   f.IsShortcut   then    
                  ProcessFolder   f    
            end   if    
      Next    
end   sub

2.將Comment內容保存到NAME中，comment2name.vbs 實習互換。語句為：

Option   Explicit    
ValidationMode   =   True    
InteractiveMode   =   im_Batch    
  
Dim   mdl   '   the   current   model    
  
'   get   the   current   active   model    
Set   mdl   =   ActiveModel    
If   (mdl   Is   Nothing)   Then    
      MsgBox   "There   is   no   current   Model "    
ElseIf   Not   mdl.IsKindOf(PdPDM.cls_Model)   Then    
      MsgBox   "The   current   model   is   not   an   Physical   Data   model. "    
Else    
      ProcessFolder   mdl    
End   If    
  
Private   sub   ProcessFolder(folder)    
On Error Resume Next   
      Dim   Tab   'running     table    
      for   each   Tab   in   folder.tables    
            if   not   tab.isShortcut   then    
                  tab.name   =   tab.comment   
                  Dim   col   '   running   column    
                  for   each   col   in   tab.columns    
                  if col.comment="" then   
                  else  
                        col.name=   col.comment    
                  end if  
                  next    
            end   if    
      next    
  
      Dim   view   'running   view    
      for   each   view   in   folder.Views    
            if   not   view.isShortcut   then    
                  view.name   =   view.comment    
            end   if    
      next    
  
      '   go   into   the   sub-packages    
      Dim   f   '   running   folder    
      For   Each   f   In   folder.Packages    
            if   not   f.IsShortcut   then    
                  ProcessFolder   f    
            end   if    
      Next    
end   sub