VST實例（5）節點（NODE） 二、節點的遍歷

二、節點的遍歷

每一個節點都有一個index值，用於描述其在相同level，相同父節點下的序號，但是，遍歷時並不能利用這個值，因為這個值是變化的，當進行排序，插入節點、刪除節點等等操作時，這個index會發生改變。

同樣的，vst.AbsoluteIndex(node)返回的是某一節點在VST中的絕對序號，也會在排序等操作時進行改變。

1、通過函數遍歷節點

下麵這些函數可以找到特定的第一個的節點：

•          function GetFirst(ConsiderChildrenAbove: Boolean = False): PVirtualNode;
•          function GetFirstChild(Node: PVirtualNode): PVirtualNode;
•          function GetFirstCutCopy(ConsiderChildrenAbove: Boolean = False): PVirtualNode;
•          function GetFirstInitialized(ConsiderChildrenAbove: Boolean = False): PVirtualNode;
•          function GetFirstNoInit(ConsiderChildrenAbove: Boolean = False): PVirtualNode;
•          function GetFirstSelected(ConsiderChildrenAbove: Boolean = False): PVirtualNode;
•          function GetFirstVisible(Node: PVirtualNode = nil; ConsiderChildrenAbove: Boolean = True; IncludeFiltered: Boolean = False): PVirtualNode;
•          function GetFirstVisibleNoInit(Node: PVirtualNode = nil; ConsiderChildrenAbove: Boolean = True; IncludeFiltered: Boolean = False): PVirtualNode;

找下一個節點的函數有：

•          function GetNext(Node: PVirtualNode; ConsiderChildrenAbove: Boolean = False): PVirtualNode;
•          function GetNextChecked(Node: PVirtualNode; ConsiderChildrenAbove: Boolean): PVirtualNode;
•          function GetNextInitialized(Node: PVirtualNode; ConsiderChildrenAbove: Boolean = False): PVirtualNode;
•          function GetNextLeaf(Node: PVirtualNode): PVirtualNode;
•          function GetNextLevel(Node: PVirtualNode; NodeLevel: Cardinal): PVirtualNode;
•          function GetNextSelected(Node: PVirtualNode; ConsiderChildrenAbove: Boolean = False): PVirtualNode;
•          function GetNextSibling(Node: PVirtualNode): PVirtualNode;
•          function GetNextVisible(Node: PVirtualNode; ConsiderChildrenAbove: Boolean = True): PVirtualNode;
•          GetNextVisible...，其它的針對可見NODE的查找下一個。

如果沒有指定節點的下一個，則返回nil。

查找最後一個節點：

•          function GetLast(Node: PVirtualNode = nil; ConsiderChildrenAbove: Boolean = False): PVirtualNode;
•          function GetLastChild(Node: PVirtualNode): PVirtualNode;
•          function GetLastVisible(Node: PVirtualNode = nil; ConsiderChildrenAbove: Boolean = True; IncludeFiltered: Boolean = False): PVirtualNode;
•          ……

下麵的代碼可以實現遍歷：

var node:pvirtualnode;

……

begin

  node:=vst.getfirst;

  repeat

     ……

     node:=vst.getnext(node);

  until node=vst.getlast;

end;

當然，上面的代碼中未包含對最後一個節點的處理。

2、遍歷函數IterateSubtree

遍歷函數的原型是：

function IterateSubtree(Node: PVirtualNode; Callback: TVTGetNodeProc; Data: Pointer; Filter: TVirtualNodeStates = []; DoInit: Boolean = False;

功能是對VST中的Node的每一個子（孫）節點進行一次回調函數（callback）的操作。如果回調函數返回了abord：=true，則終止遍歷，並返回終止遍歷的節點。

如果參數node=nil，則對所有的節點進行遍歷。

data是傳入回調函數的指針參數，而Filter是篩選器，如果為空，則對所有的節點進行遍歷，否則只對具有篩選器狀態的節點進行遍歷。例如如果filter包含“vsvisible”，則只對可見的節點進行遍歷。

回調函數的格式是：

TVTGetNodeProc = procedure (Sender: TBaseVirtualTree; Node: PVirtualNode; Data: Pointer; var Abort: Boolean) of object;

其中data指的就是IterateSubtree中指向的數據data。

以本程式為例，當編輯框中內容發生改變，則立即查找符合條件的節點，並設置為可見，不符合條件的節點則設置為不可見。

代碼如下：

procedure TForm2.lbledt1Change(Sender: TObject);

var data:pchar;

begin

   data:=PChar(lbledt1.Text);

   //beginupdate之後的語句只有當遇到endupdate之後才進行顯示刷新

   //可以避免程式的頻繁刷新導致的抖動，加快程式的運行。

   vst.BeginUpdate;

   //調用遍歷函數，傳入的參數是文本框的文本

   vst.IterateSubtree(nil,getnodebystr,data);

   //讓所有符合條件的節點展開

   vst.FullExpand();

   vst.EndUpdate;

end;

回調函數getnodebystr的定義和代碼如下：

procedure GETNODEBYSTR(Sender: TBaseVirtualTree; Node: PVirtualNode; Data: Pointer; var Abort: Boolean);

……

procedure TForm2.GETNODEBYSTR(Sender: TBaseVirtualTree; Node: PVirtualNode; Data: Pointer; var Abort: Boolean);

var str1,str2:string;

begin

  str1:=string(Data).Trim.ToUpper;

  with pcodes(Sender.GetNodeData(node))^ do

  begin

    str2:=icao+'|'+iata+'|'+names;

  end;

  str2:=str2.Trim.ToUpper;

  if str2.Contains(str1) or str1.IsEmpty then

  begin

    Sender.FullyVisible[NODE]:=true;

    //下麵部分是設置可見的另一種寫法，如果不包含子節點，則效率會更高

    //sender.IsVisible[node]:=True;

    //if Sender.GetNodeLevel(node)>0 then//有父節點的情況下

    //  Sender.IsVisible[Node.Parent]:=True;

  end

  else

  begin

    Sender.IsVisible[node]:=false;

  end;

end;

本程式共有630個節點，在執行中完全可以實時查詢無停頓。VST的效率非常高。

3、節點序列

前面我們提到過vst.SelectedNodes和vst.checkedNodes都是節點序列，節點序列的定義是這樣的：

TVTVirtualNodeEnumeration = record

  objectprivateFMode: TVZVirtualNodeEnumerationMode;

  FTree: TBaseVirtualTree;

  FConsiderChildrenAbove: Boolean;

  FNode: PVirtualNode;

  FNodeLevel: Cardinal;

  FState: TCheckState;

  FIncludeFiltered: Boolean;

end;

並提供了一個函數：GetEnumerator，用於從FTREE中獲取具有指定特征的節點，例如checkednodes就是從VST中取得具有某種TCheckState屬性的所有節點，而SelectedNodes則是獲得具有selected屬性的節點（node的states屬性），所以你也可以寫自己的節點序列程式。

函數GetEnumerator返回的是一個TVTVirtualNodeEnumerator類型的結構（record），其具體使用代碼例子如下：

var node:PVirtualNode;

begin

  with vst.CheckedNodes().GetEnumerator do

  begin

    MoveNext;

repeat

      node:=Current;

      ……

    until not MoveNext;

  end;

end;

需要註意的是，一定要針對GetEnumerator返回的結構進行操作，不能一次次的調用GetEnumerator.current 和GetEnumerator.movenext，因為每次調用一次GetEnumerator就會生成一次序列。

請註意，調用GetEnumerator後，current並沒有對應某個NODE，需要調用一次movenext後，current才指向第一個node，每調用一次movenext，current指向下一個node，如果已經是最後一個node，調用movenext則返回false.

程式中寫了一小段代碼，用於把選中的機場資料導出到一個CSV文件中。

procedure TForm2.N5Click(Sender: TObject);

var sl:TStringList;s:string;

begin

  if vst.CheckedCount=0 then Exit;

  sl:=TStringList.Create;

  with vst.CheckedNodes(csCheckedNormal).GetEnumerator do

  begin

    MoveNext;

    repeat

       //如果是根節點，即FIR，則跳到下一個迴圈

       if vst.GetNodeLevel(current)=0 then  Continue;

       s:='';

       if Assigned(current) then

       with pcodes(vst.GetNodeData(current))^ do

       begin

         s:=s.Join(',',[icao,iata,names,rwy_style,apt_type]);

       end;

       sl.Add(s);

    until not MoveNext;

  end;

  //直接把文檔存儲到執行文件所在目錄的文件中

  sl.SaveToFile('checkedapts.csv');

  FreeAndNil(sl);

end;